(Visual FoxPro) SOAP Web Service (HTTP POST)

Demonstrates how to call PostXml to call a SOAP web service.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL loXml
LOCAL lnSuccess
LOCAL lcStrXml
LOCAL lnResponseStatusCode
LOCAL loHttp
LOCAL lcEndPoint
LOCAL loResp
LOCAL loXmlResp

* This example requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* --------------------------------------------------------------------------------
* Also see Chilkat's Online WSDL Code Generator
* to generate code and SOAP Request and Response XML for each operation in a WSDL.
* --------------------------------------------------------------------------------

* This example uses a live web service at:
* http://www.webservicex.net/uklocation.asmx
* It gets the UK town,Postcode and County by Postcode(First Section of Post Code)

* The SOAP XML will look like this:
* <?xml version="1.0" encoding="utf-8"?>
* <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
*   <soap:Body>
*     <GetUKLocationByPostCode xmlns="http://www.webserviceX.NET">
*       <PostCode>string</PostCode>
*     </GetUKLocationByPostCode>
*   </soap:Body>
* </soap:Envelope>

* For this example's sake, we'll load the XML from a file.  We'll test using PostCode "E3".  
* The SOAP XML for this example may be downloaded from:
* http://www.chilkatsoft.com/testData/ukPostCodeSoap.xml
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Xml')
loXml = CreateObject('Chilkat.Xml')
lnSuccess = loXml.LoadXmlFile("ukPostCodeSoap.xml")
IF (lnSuccess <> 1) THEN
    ? loXml.LastErrorText
    RELEASE loXml
    CANCEL
ENDIF

lcStrXml = loXml.GetXml()

* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Http')
loHttp = CreateObject('Chilkat.Http')

* We'll need to add this in the HTTP header:
* SOAPAction: "http://www.webserviceX.NET/GetUKLocationByPostCode"
loHttp.SetRequestHeader("SOAPAction","http://www.webserviceX.NET/GetUKLocationByPostCode")

* Some services expect the content-type in the HTTP header to be "application/xml" while
* other expect text/xml.  The default sent by Chilkat is "application/xml", but this web service
* expects "text/xml".  Therefore, change the content-type:
loHttp.SetRequestHeader("Content-Type","text/xml; charset=utf-8")

* The endpoint for this soap service is:
lcEndPoint = "http://www.webservicex.net/uklocation.asmx"

* Note: This particular web service was live and functioning at the time this example
* was written.  It is possible that as time progresses, this web service will no longer
* be availble...
loResp = loHttp.PostXml(lcEndPoint,lcStrXml,"utf-8")
IF (loHttp.LastMethodSuccess <> 1) THEN
    ? loHttp.LastErrorText
    ? "LastHeader:"
    ? loHttp.LastHeader
    RELEASE loXml
    RELEASE loHttp
    CANCEL
ENDIF

lnResponseStatusCode = loResp.StatusCode
* You may wish to verify that the responseStatusCode equals 200...
? "Response Status Code: " + STR(lnResponseStatusCode)

* You may examine the exact HTTP header sent with the POST like this:
? "LastHeader:"
? loHttp.LastHeader

* Examine the XML returned by the web service:
? "XML Response:"
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Xml')
loXmlResp = CreateObject('Chilkat.Xml')
loXmlResp.LoadXml(loResp.BodyStr)
? loXmlResp.GetXml()

* Use this online tool to generate parsing code from response XML: 
* Generate Parsing Code from XML

RELEASE loResp

RELEASE loXml
RELEASE loHttp
RELEASE loXmlResp