(Visual FoxPro) Send High Priority Email (SMTP, X-Priority header)

Demonstrates how to send high-priorty email (or lower priority email) by setting the X-Priority header field.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL loMailman
LOCAL loEmail
LOCAL lnSuccess

* This example requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* The mailman object is used for sending and receiving email.
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.MailMan')
loMailman = CreateObject('Chilkat.MailMan')

* Set the SMTP server (obviously, use your SMTP server, not chilkatsoft.com)
loMailman.SmtpHost = "smtp.chilkatsoft.com"

* Set the SMTP login/password (if required)
loMailman.SmtpUsername = "myUsername"
loMailman.SmtpPassword = "myPassword"

* Create a new email object
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Email')
loEmail = CreateObject('Chilkat.Email')

loEmail.Subject = "This is a test"
loEmail.Body = "This is a test"
loEmail.From = "Chilkat Support <support@chilkatsoft.com>"
lnSuccess = loEmail.AddTo("Chilkat Admin","admin@chilkatsoft.com")
* To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

* To send high-priority email, 
* add the X-Priority header field with the value "1" 
* to indicate highest-priority.
* A value of "3" is normal, which is the same as not setting
* the X-Priority header at all, and "5" is the lowest. 
* "2" and "4" are in-betweens.

* Microsoft Outlook might add the following headers when
* sending high-priority email.

* X-Priority: 1 (Highest) 
* X-MSMail-Priority: High 
* Importance: High 

* The X-Priority header alone is enough to make the email high-priority.

loEmail.AddHeaderField("X-Priority","1")

* Call SendEmail to connect to the SMTP server and send.
* The connection (i.e. session) to the SMTP server remains
* open so that subsequent SendEmail calls may use the
* same connection.  
lnSuccess = loMailman.SendEmail(loEmail)
IF (lnSuccess <> 1) THEN
    ? loMailman.LastErrorText
    RELEASE loMailman
    RELEASE loEmail
    CANCEL
ENDIF

lnSuccess = loMailman.CloseSmtpConnection()
IF (lnSuccess <> 1) THEN
    ? "Connection to SMTP server not closed cleanly."
ENDIF

? "Mail Sent!"

RELEASE loMailman
RELEASE loEmail