Visual FoxPro
Send a Simple HTML Email

Demonstrates how to send a simple HTML email (i.e. with no images, style sheets, etc.).
Chilkat Visual FoxPro Downloads

Visual FoxPro
LOCAL lnSuccess
LOCAL loMailman
LOCAL loEmail

lnSuccess = 0

* This example requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* The mailman object is used for sending and receiving email.
loMailman = CreateObject('Chilkat.MailMan')

* Set the SMTP server.
loMailman.SmtpHost = "smtp.chilkatsoft.com"

* Set the SMTP login/password (if required)
loMailman.SmtpUsername = "myUsername"
loMailman.SmtpPassword = "myPassword"

* Create a new email object
loEmail = CreateObject('Chilkat.Email')

loEmail.Subject = "This is a test"
loEmail.SetHtmlBody('<html><body><p>This is <b>bold text</b>, this is a <a href="http://www.chilkatsoft.com/">hyperlink</a></p></body></html>')
loEmail.From = "Chilkat Support <support@chilkatsoft.com>"
lnSuccess = loEmail.AddTo("Chilkat Admin","admin@chilkatsoft.com")

* Call SendEmail to connect to the SMTP server and send.
* The connection (i.e. session) to the SMTP server remains
* open so that subsequent SendEmail calls may use the
* same connection.  
lnSuccess = loMailman.SendEmail(loEmail)
IF (lnSuccess <> 1) THEN
    ? loMailman.LastErrorText
    RELEASE loMailman
    RELEASE loEmail
    CANCEL
ENDIF

* Some SMTP servers do not actually send the email until 
* the connection is closed.  In these cases, it is necessary to
* call CloseSmtpConnection for the mail to be  sent.  
* Most SMTP servers send the email immediately, and it is 
* not required to close the connection.  We'll close it here
* for the example:
lnSuccess = loMailman.CloseSmtpConnection()
IF (lnSuccess <> 1) THEN
    ? "Connection to SMTP server not closed cleanly."
ENDIF

? "Mail Sent!"

RELEASE loMailman
RELEASE loEmail