(Visual FoxPro) Send Signed Email using PFX File

Demonstrates how to send a signed email using a digital certificate w/ private key stored in a PFX file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL loMailman
LOCAL loEmail
LOCAL lnSuccess

* This example requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* The mailman object is used for sending and receiving email.
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.MailMan')
loMailman = CreateObject('Chilkat.MailMan')

* Set the SMTP server.
loMailman.SmtpHost = "smtp.mymailserver.com"

* Create a new email object
* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Email')
loEmail = CreateObject('Chilkat.Email')

loEmail.Subject = "This email is signed"
loEmail.Body = "This is a digitally signed mail"
loEmail.From = "Chilkat Admin <admin@chilkatsoft.com>"
lnSuccess = loEmail.AddTo("Chilkat Support","support@chilkatsoft.com")

* Indicate that the email should be sent signed.
loEmail.SendSigned = 1

* Tell the mailman to use a PFX file as a source for locating
* the certificate and private key required for signing.
* The certificate chosen for signing will be the one that
* matches the sender's email address, which also has
* a private key.  All intermediate certs in the chain of 
* authentication, up to and including the root, will
* be included in the signature.
lnSuccess = loMailman.AddPfxSourceFile("/pfx_files/chilkatsoft_secret.pfx","secret")
IF (lnSuccess <> 1) THEN
    ? loMailman.LastErrorText
    RELEASE loMailman
    RELEASE loEmail
    CANCEL
ENDIF

* Signed email can be sent in two different ways.  
* In a multipart/signed email, the signature is attached as a separate MIME part.
* In an opaque email (signedData) the content of the email is encapsulated within the signature
* and the email is sent as "application/pkcs7-mime". 
* Either should be fine, but some receiving systems might require one or the other..
loMailman.OpaqueSigning = 0

* Send a signed email.
lnSuccess = loMailman.SendEmail(loEmail)
IF (lnSuccess <> 1) THEN
    ? loMailman.LastErrorText
ELSE
    * The LastErrorText property provides information
    * even when successful.
    ? loMailman.LastErrorText
    ? "Mail Sent!"
ENDIF

RELEASE loMailman
RELEASE loEmail