(Visual FoxPro) SharePoint List Document Libraries

See more SharePoint Examples

This example shows how to use Chilkat's HttpCurl class to list the document libraries in a SharePoint site. In Microsoft Graph, SharePoint document libraries are represented as drives. The example demonstrates how HttpCurl can automatically resolve a SharePoint site name to its Microsoft Graph site ID, then use that ID to retrieve and display the site's document libraries.

Note: This example requires Chilkat v11.5.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL lnSuccess
LOCAL loJsonAuth
LOCAL loCurl
LOCAL lcCurlCommand
LOCAL lnStatusCode
LOCAL loJson
LOCAL i
LOCAL lnNumDrives

lnSuccess = 0

* This example retrieves the document libraries for a SharePoint site.
* 
* In Microsoft Graph terminology, a document library is represented as a "drive".
* The example demonstrates how HttpCurl can automatically resolve a SharePoint
* site name to a site ID before requesting the site's document libraries.

lnSuccess = 0

* --------------------------------------------------------------------------------------------------------
* Before running this example, create an Azure App Registration and grant it
* the Microsoft Graph permissions required to access SharePoint.
* 
* The application will authenticate using OAuth2 Client Credentials.
* See:
* How to Create SharePoint App Registration for OAuth 2.0 Client Credentials
* --------------------------------------------------------------------------------------------------------

* Build a JSON authentication configuration.
* HttpCurl will use this information to automatically obtain OAuth2 access tokens.
loJsonAuth = CreateObject('Chilkat.JsonObject')

* Enable secret lookup.
* 
* Instead of hard-coding sensitive values such as the client ID,
* client secret, and token endpoint, secret specification strings
* are used.  Chilkat automatically retrieves the actual values from
* Windows Credential Manager (Windows) or Apple Keychain (macOS).
* 
* See:
* Secret Specification Strings
loJsonAuth.EnableSecrets = 1

lnSuccess = loJsonAuth.UpdateString("oauth2.client_id","!!sharepoint|oauth2|client_id")
IF (lnSuccess = 1) THEN
    lnSuccess = loJsonAuth.UpdateString("oauth2.client_secret","!!sharepoint|oauth2|client_secret")
ENDIF

IF (lnSuccess = 1) THEN
    lnSuccess = loJsonAuth.UpdateString("oauth2.token_endpoint","!!sharepoint|oauth2|token_endpoint")
ENDIF

IF (lnSuccess = 0) THEN
    ? loJsonAuth.LastErrorText
    RELEASE loJsonAuth
    CANCEL
ENDIF

* Request Microsoft Graph permissions that were granted to the application.
loJsonAuth.UpdateString("oauth2.scope","https://graph.microsoft.com/.default")

* ---------------------------------------------------------------------------------------------------

loCurl = CreateObject('Chilkat.HttpCurl')

* Associate the OAuth2 configuration with HttpCurl.
* 
* When the request is executed, Chilkat automatically obtains an access token
* if needed and adds the Authorization: Bearer header to the HTTP request.
loCurl.SetAuth(loJsonAuth)

* Define variables whose values are already known.
* 
* These variables are referenced in the curl command using
* {{variable_name}} substitution syntax.
loCurl.SetVar("sharepoint_hostname","example.sharepoint.com")
loCurl.SetVar("site_name","test")

* The document libraries endpoint requires a Microsoft Graph site ID.
* 
* Because the application only knows the SharePoint site name,
* HttpCurl must first retrieve the corresponding site ID.
* 
* Define a function that can resolve the site_id variable when needed.
* HttpCurl may execute this function automatically if it determines that
* site_id is required by another request.
loCurl.AddFunction("getSite","GET https://graph.microsoft.com/v1.0/sites/root:/sites/{{site_name}}")

* Extract the "id" field from the getSite response and store it
* in the HttpCurl variable named "site_id".
* 
* Any later request that references {{site_id}} can use this value.
loCurl.AddOutput("getSite","id","site_id")

* The target Microsoft Graph request:
* 
* curl -X GET \"https://graph.microsoft.com/v1.0/sites/{{site_id}}/drives
* 
* This request returns the document libraries belonging to the site.
* 
* Microsoft Graph refers to document libraries as "drives",
* so each object in the response represents one document library.
* 
* No Authorization header is included because HttpCurl automatically
* adds it when OAuth2 authentication is configured.
lcCurlCommand = 'curl -X GET "https://graph.microsoft.com/v1.0/sites/{{site_id}}/drives"'

* Execute the request.
* 
* HttpCurl examines the target curl command and determines that
* the variable {{site_id}} is required.
* 
* Because site_id is not yet known, HttpCurl searches for a function
* capable of producing it.  The getSite function provides the "id"
* output, which is mapped to the site_id variable.
* 
* The execution plan becomes:
* 
*   1) Execute getSite to obtain site_id.
*   2) Substitute {{site_id}} into the target request.
*   3) Execute the drives request.
* 
* The final HTTP response returned by DoYourThing is always the
* response from the target curl command, which is the last step in the plan.
lnSuccess = loCurl.DoYourThing(lcCurlCommand)
IF (lnSuccess = 0) THEN
    ? loCurl.LastErrorText
    RELEASE loJsonAuth
    RELEASE loCurl
    CANCEL
ENDIF

* A successful Graph response should return HTTP 200.
* Any other status code typically indicates an authentication,
* permission, or resource lookup error.
lnStatusCode = loCurl.StatusCode
IF (lnStatusCode <> 200) THEN
    ? loCurl.ResponseBodyStr
    ? "status code = " + STR(lnStatusCode)
    RELEASE loJsonAuth
    RELEASE loCurl
    CANCEL
ENDIF

* The response body contains a JSON array named "value".
* Each element of the array describes a SharePoint document library.
loJson = CreateObject('Chilkat.JsonObject')
loJson.EmitCompact = 0
loCurl.GetResponseJson(loJson)
? loJson.Emit()

* Iterate over the document libraries returned by Microsoft Graph
* and display selected properties for each library.
i = 0
lnNumDrives = loJson.SizeOfArray("value")
DO WHILE i < lnNumDrives
    loJson.I = i
    ? "name: " + loJson.StringOf("value[i].name")
    ? "description: " + loJson.StringOf("value[i].description")
    ? "id: " + loJson.StringOf("value[i].id")
    ? "webUrl: " + loJson.StringOf("value[i].webUrl")
    ? "displayName: " + loJson.StringOf("value[i].createdBy.user.displayName")
    ? "-"
    i = i + 1
ENDDO

? "Success."

RELEASE loJsonAuth
RELEASE loCurl
RELEASE loJson