Visual FoxPro

GeoOp OAuth2 Authorisation Code Grant (Public App)

See more OAuth2 Examples

Demonstrates how to get an access token for a GeoOp Third-Party Public Application using the Authorisation Code Grant flow. Visual FoxPro

LOCAL lnSuccess
LOCAL loOauth2
LOCAL lcUrl
LOCAL lnNumMsWaited
LOCAL loFac

lnSuccess = 0

* It requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

loOauth2 = CreateObject('Chilkat.OAuth2')

* This should match the Site URL configured for your GeoOp (non-Server) Application, such as "http://localhost:3017/"
loOauth2.ListenPort = 3017

loOauth2.AuthorizationEndpoint = "https://login.geoop.com/oauth2/code"
loOauth2.TokenEndpoint = "https://login.geoop.com/oauth2/token"

* Replace the client ID with an actual value.
loOauth2.ClientId = "GEOOP-APPLICATION-ID"
* The ClientSecret should remain empty for a GeoOp public application
loOauth2.ClientSecret = ""

* We need a few special settings for GeoOp
loOauth2.Scope = "default"
loOauth2.CodeChallenge = 0
* Setting LocalHost equal to "none" prevents the "redirect_uri" query param from being sent in the initial HTTP request.
* Note: The GeoOp Application should still have a redirect URL specified as "http://localhost:3017/", where the port
* number matches the ListenPort above.
loOauth2.LocalHost = "none"

* Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
lcUrl = loOauth2.StartAuth()
IF (loOauth2.LastMethodSuccess <> 1) THEN
    ? loOauth2.LastErrorText
    RELEASE loOauth2
    CANCEL
ENDIF

* Launch the default browser on the system and navigate to the url.
* The LaunchBrowser method was added in Chilkat v10.1.2.
lnSuccess = loOauth2.LaunchBrowser(lcUrl)
IF (lnSuccess = 0) THEN
    ? loOauth2.LastErrorText
    RELEASE loOauth2
    CANCEL
ENDIF

* Wait for the user to approve or deny authorization in the browser.
lnNumMsWaited = 0
DO WHILE (lnNumMsWaited < 90000) AND (loOauth2.AuthFlowState < 3)
    loOauth2.SleepMs(100)
    lnNumMsWaited = lnNumMsWaited + 100
ENDDO

* If the browser does not respond within the specified time, AuthFlowState will be:
* 
* 1: Waiting for Redirect – The OAuth2 background thread is waiting for the browser's redirect request.
* 2: Waiting for Final Response – The thread is awaiting the final access token response.
* In either case, cancel the background task initiated by StartAuth.

IF (loOauth2.AuthFlowState < 3) THEN
    loOauth2.Cancel()
    ? "No response from the browser!"
    RELEASE loOauth2
    CANCEL
ENDIF

* Check AuthFlowState to determine if authorization was granted, denied, or failed:
* 
* 3: Success – OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
* 4: Access Denied – OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
* 5: Failure – OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

IF (loOauth2.AuthFlowState = 5) THEN
    ? "OAuth2 failed to complete."
    ? loOauth2.FailureInfo
    RELEASE loOauth2
    CANCEL
ENDIF

IF (loOauth2.AuthFlowState = 4) THEN
    ? "OAuth2 authorization was denied."
    ? loOauth2.AccessTokenResponse
    RELEASE loOauth2
    CANCEL
ENDIF

IF (loOauth2.AuthFlowState <> 3) THEN
    ? "Unexpected AuthFlowState:" + STR(loOauth2.AuthFlowState)
    RELEASE loOauth2
    CANCEL
ENDIF

? "OAuth2 authorization granted!"
? "Access Token = " + loOauth2.AccessToken

* Save the entire JSON response, which includes the access token, for future calls.
* The JSON AccessTokenResponse looks like this:
* {"access_token":"e6dqdG....mzjpT04w==","token_type":"Bearer","expires_in":2592000,"owner_id":984236}

loFac = CreateObject('Chilkat.FileAccess')
loFac.WriteEntireTextFile("qa_data/tokens/geoop.json",loOauth2.AccessTokenResponse,"utf-8",0)

? "Success."

RELEASE loOauth2
RELEASE loFac