(Visual FoxPro) AES Encrypt String (utf-8 byte representation) and return Base64

Demonstrates how to AES encrypt the utf-8 byte representation of a string and return in base64 format.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL loCrypt
LOCAL lcIvHex
LOCAL lcKeyHex
LOCAL lcEncryptedStr
LOCAL lcUrlEncoded
LOCAL lcEncBase64Url
LOCAL lcEncBase64
LOCAL lcOriginalStr

* This example requires the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Crypt2')
loCrypt = CreateObject('Chilkat.Crypt2')

loCrypt.CryptAlgorithm = "aes"
loCrypt.CipherMode = "cbc"
loCrypt.KeyLength = 256
loCrypt.Charset = "utf-8"
loCrypt.EncodingMode = "base64"

lcIvHex = "000102030405060708090A0B0C0D0E0F"
loCrypt.SetEncodedIV(lcIvHex,"hex")
lcKeyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
loCrypt.SetEncodedKey(lcKeyHex,"hex")

lcEncryptedStr = loCrypt.EncryptStringENC("This is the original string")
? lcEncryptedStr

* Let's say we want to URL encode the base64 string..
loCrypt.CryptAlgorithm = "none"
loCrypt.EncodingMode = "url"
lcUrlEncoded = loCrypt.EncryptStringENC(lcEncryptedStr)
? lcUrlEncoded

* Sample output:

*  q3fmgEqjqa9o//ZS6aPuh4Wtbrrxx/WOIQSKeVnesZg=
*  q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D

* -------------------------------------------------------------------
* Now let's do the reverse...
* 

* We start with a string that is the binary encrypted data, base64 encoded, and then URL encoded.
lcEncBase64Url = "q3fmgEqjqa9o%2F%2FZS6aPuh4Wtbrrxx%2FWOIQSKeVnesZg%3D"

* We'll use the same crypt object.  If using a new instance of the crypt object,
* make sure *all* settings are identical:  the algorithm, cipher mode, key length, charset, encoding mode, IV, and secret key.

* Decode from URL...
loCrypt.CryptAlgorithm = "none"
loCrypt.EncodingMode = "url"
lcEncBase64 = loCrypt.DecryptStringENC(lcUrlEncoded)
? lcEncBase64

* Now decrypt...
loCrypt.CryptAlgorithm = "aes"
loCrypt.EncodingMode = "base64"
lcOriginalStr = loCrypt.DecryptStringENC(lcEncBase64)
? lcOriginalStr

RELEASE loCrypt