(Excel) Chilkat Zip API Concepts

This example helps clarify some common misconceptions w/ using the Chilkat Zip API.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim zip As Chilkat.Zip
Set zip = Chilkat.NewZip

' To clarify some concepts, this example will create a new .zip containing 2 files.

' The NewZip method is called to initialize the zip object to a new and empty state.
' It does not actually create the .zip file.  It simply intializes the object.
' if the zip object did not contain anything previously, then this method could be skipped
' altogether.  It has the side-effect of setting the zip.FileName property.

success = zip.NewZip("test.zip")
If (success <> True) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' The FileName property should now contain "test.zip".  This is the name of the .zip
' that is written when WriteZip or WriteZipAndClose is called.
Debug.Print "zip filename = "; zip.FileName

' When a file is "appended" to the zip object, we are really just appending a reference
' to the file in the filesystem.  A "zip entry" is added to the zip object and this entry
' can be one of several types.  It can point to a file.  It can contain uncompressed binary
' or text data, it can point to an entry in the already-opened zip (if we had called OpenZip 
' instead), etc.  

' Now.. add a reference to a single file by calling AppendOneFileOrDir
' Note: On Windows, forward slashes are equivalent to backslashes

saveExtraPath = False
success = zip.AppendOneFileOrDir("/temp/abc123/HelloWorld123.txt",saveExtraPath)
If (success <> True) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' We now have a zip object with one entry, which points to the file /temp/abc123/HelloWorld123.txt
' If desired, we could change the filename of the zip entry so that when the zip is written,
' the file has a different name:

Set entry = zip.GetEntryByIndex(0)
entry.FileName = "helloWorld.txt"

' When the zip is actually written, the entry's data will stream from /temp/abc123/HelloWorld123.txt
' and be compressed into an entry within the .zip having the filename "helloWorld.txt"

' Now add another entry, this time from a string containing the file content:
Set entry = zip.AppendString2("HelloWorld2.txt","hello world!","utf-8")

' Examine the entries in the zip so far..
' Each entry can be one of the following types:

' 0 -- Mapped Entry: An entry in an existing Zip file.
' 1 -- File Entry: A file not yet in memory, but referenced. 
'      These entries are added by calling AppendFiles, AppendFilesEx, AppendOneFileOrDir, etc.
' 2 -- Data Entry: An entry containing uncompressed data from memory. 
'      These entries are added by calling AppendData, AppendString, etc.
' 3 -- Null Entry: An entry that no longer exists in the .zip.
' 4 -- New Directory Entry: A directory entry added by calling AppendNewDir. 


n = zip.NumEntries
For i = 0 To n - 1

    Set entry = zip.GetEntryByIndex(i)
    Debug.Print entry.FileName; ", type="; entry.EntryType

Next

' Write the "test.zip" file.
success = zip.WriteZip()
If (success <> True) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' Our zip object still contains 2 entries, but now they point to the entries within the 
' test.zip  (We called WriteZip, which writes the .zip but does not close it.  Instead,
' the entries of the zip object are updated to become "mapped" entries.
' For example:

n = zip.NumEntries
For i = 0 To n - 1

    Set entry = zip.GetEntryByIndex(i)
    Debug.Print entry.FileName; ", type="; entry.EntryType

Next

' Finally, close the zip
zip.CloseZip