(Excel) SOAP Web Service (HTTP POST)

Demonstrates how to call PostXml to call a SOAP web service.

Download Excel Class Modules Chilkat Excel Class Modules

Dim http As Chilkat.Http
Set http = Chilkat.NewHttp

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a live web service at:
' http://www.webservicex.net/uklocation.asmx
' It gets the UK town,Postcode and County by Postcode(First Section of Post Code)

' The SOAP XML will look like this:
' <?xml version="1.0" encoding="utf-8"?>
' <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'   <soap:Body>
'     <GetUKLocationByPostCode xmlns="http://www.webserviceX.NET">
'       <PostCode>string</PostCode>
'     </GetUKLocationByPostCode>
'   </soap:Body>
' </soap:Envelope>

' For this example's sake, we'll load the XML from a file.  We'll test using PostCode "E3".  
' The SOAP XML for this example may be downloaded from:
' http://www.chilkatsoft.com/testData/ukPostCodeSoap.xml
Dim xml As Chilkat.Xml
Set xml = Chilkat.NewXml
success = xml.LoadXmlFile("ukPostCodeSoap.xml")
If (success <> True) Then
    Debug.Print xml.LastErrorText
    Exit Sub
End If


strXml = xml.GetXml()

' We'll need to add this in the HTTP header:
' SOAPAction: "http://www.webserviceX.NET/GetUKLocationByPostCode"
http.SetRequestHeader "SOAPAction","http://www.webserviceX.NET/GetUKLocationByPostCode"

' Some services expect the content-type in the HTTP header to be "application/xml" while
' other expect text/xml.  The default sent by Chilkat is "application/xml", but this web service
' expects "text/xml".  Therefore, change the content-type:
http.SetRequestHeader "Content-Type","text/xml; charset=utf-8"

' The endpoint for this soap service is:

endPoint = "http://www.webservicex.net/uklocation.asmx"

' Note: This particular web service was live and functioning at the time this example
' was written.  It is possible that as time progresses, this web service will no longer
' be availble...

Set resp = http.PostXml(endPoint,strXml,"utf-8")
If (http.LastMethodSuccess <> True) Then
    Debug.Print http.LastErrorText
    Debug.Print "LastHeader:"
    Debug.Print http.LastHeader
    Exit Sub
End If

responseStatusCode = resp.StatusCode
' You may wish to verify that the responseStatusCode equals 200...
Debug.Print "Response Status Code: "; responseStatusCode

' You may examine the exact HTTP header sent with the POST like this:
Debug.Print "LastHeader:"
Debug.Print http.LastHeader

' Examine the XML returned by the web service:
Debug.Print "XML Response:"
Dim xmlResp As Chilkat.Xml
Set xmlResp = Chilkat.NewXml
success = xmlResp.LoadXml(resp.BodyStr)
Debug.Print xmlResp.GetXml()

' Use this online tool to generate parsing code from response XML: 
' Generate Parsing Code from XML