(Excel) RSAES-OAEP Encrypt String with AES-128 Content Encryption and SHA256

Encrypts a string using RSAES-OAEP with SHA256 and AES-128 content encryption to produce PKCS7 output (base64 encoded).

Note: This example requires Chilkat v9.5.0.67 or greater.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat Crypt API to have been previously unlocked.
' See Unlock Chilkat Crypt for sample code.

' First build a string to be encrypted
Dim sb As Chilkat.StringBuilder
Set sb = Chilkat.NewStringBuilder

i = 1
Do While i < 25
    Dim success As Boolean
    success = sb.AppendInt(i)
    success = sb.Append(" the quick brown fox jumped over the lazy dog." & vbCrLf)
    i = i + 1
Loop

Debug.Print sb.GetAsString()

' The string to be encrypted looks like this:

' 1 the quick brown fox jumped over the lazy dog.
' 2 the quick brown fox jumped over the lazy dog.
' 3 the quick brown fox jumped over the lazy dog.
' 4 the quick brown fox jumped over the lazy dog.
' 5 the quick brown fox jumped over the lazy dog.
' 6 the quick brown fox jumped over the lazy dog.
' ...

' Load a digital certificate. 
' We don't need the private key for encryption.
' Only the public key is needed (which is included in a certificate).
Dim cert As Chilkat.Cert
Set cert = Chilkat.NewCert

success = cert.LoadFromFile("qa_data/rsaes-oaep/cert.pem")
If (success <> True) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

' Tell the crypt object to use the certificate.
success = crypt.SetEncryptCert(cert)

' Indicate that we want PKI encryption (i.e. public-key infrastructure)
' to produce a CMS message (Cryptographic Message Syntax/PKCS7),
' that is be created with RSAES-OAEP padding, SHA256, and AES-128 for the
' bulk encryption.
crypt.CryptAlgorithm = "pki"
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 128
crypt.OaepHash = "sha256"
crypt.OaepPadding = True

' Also, don't forget to be specific about the character encoding (byte representation) of the
' string to be encrypted.
crypt.Charset = "utf-8"

' Now indicate that the PKCS7 output is to be returned in the base64 encoding.
crypt.EncodingMode = "base64"


base64Pkcs7 = crypt.EncryptStringENC(sb.GetAsString())
If (crypt.LastMethodSuccess <> True) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Show the output
Debug.Print base64Pkcs7

' This base64 can be copy-and-pasted into the form at http://lapo.it/asn1js/
' to verify that all the chosen algorithms were indeed used.

Debug.Print "OK."