(Excel) RSA Encrypting Symmetric Secret Key

The RSA encryption algorithm is computationally expensive. It is not the best choice for encrypting large amounts of data. Symmetric encryption algorithms such as AES (i.e. Rijndael) or Blowfish are much more efficient. A typical application scenario is that you want to send encrypted messages to a partner, but you don't want to send the symmetric key unprotected. A solution is to generate a public/private RSA key pair and provide your partner with the public key (in advance). You may then encrypt the symmetric algorithm's key using the RSA private key. Next, encrypt the message using the symmetric algorithm, and send your partner both the encrypted key and encrypted message. Your partner decrypts by first RSA decrypting the key, and then uses the decrypted symmetric key to decrypt the message content.

Download Excel Class Modules Chilkat Excel Class Modules

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rsa As Chilkat.Rsa
Set rsa = Chilkat.NewRsa
Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

' Load a public/private key pair from a .snk key file.
' Assume you have already provided your partner with 
' the public key part of the key pair.

xmlKey = rsa.SnkToXml("chilkat2.snk")

' Alternatively, you may generate a public/private key pair 
' by calling GenerateKey..

' Import the private key into the RSA instance.

success = rsa.ImportPrivateKey(xmlKey)

' Our message data will be encrypted using 128-bit AES
' encryption, using CBC (cipher-block chaining).
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

' Generate a 128-bit secret key from a passphrase and return it as a hex string.

secretKey = crypt.GenEncodedSecretKey("secret","hex")
Debug.Print "Unencrypted Key: "; secretKey

' Use the key we generated:
crypt.SetEncodedKey secretKey,"hex"

' RSA encrypt the secret key and return as a hex string:
rsa.EncodingMode = "hex"

bUsePrivateKey = False

encryptedKey = rsa.EncryptStringENC(secretKey,bUsePrivateKey)

' Symmetric encrypt a message.  For this example the message
' is very short, but typically this is where a large amount
' of data may be encrypted.
crypt.EncodingMode = "base64"

encryptedText = crypt.EncryptStringENC("Hello World!")

' Show our encrypted key and encrypted text:
Debug.Print "Encrypted Key: "; encryptedKey
Debug.Print "Encrypted Text: "; encryptedText

' Assume we sent these strings to our partner...

' Here's what we do at the partner end:
success = rsa.ImportPublicKey(xmlKey)

' First, decrypt the encryptedKey:
bUsePrivateKey = True

decryptedKey = rsa.DecryptStringENC(encryptedKey,bUsePrivateKey)
Debug.Print "Decrypted Key: "; decryptedKey

' Set our crypt object's properties and secret key:
Dim crypt2 As Chilkat.Crypt2
Set crypt2 = Chilkat.NewCrypt2
crypt2.CryptAlgorithm = "aes"
crypt2.CipherMode = "cbc"
crypt2.KeyLength = 128
crypt2.EncodingMode = "base64"
crypt2.SetEncodedKey decryptedKey,"hex"

' Decrypt the message:

decryptedText = crypt2.DecryptStringENC(encryptedText)
Debug.Print "Decrypted Text: "; decryptedText