(Excel) POP3 Read S/MIME Encrypted Email

Read S/MIME encrypted email.

Download Excel Class Modules Chilkat Excel Class Modules

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
Dim mailman As Chilkat.MailMan
Set mailman = Chilkat.NewMailMan

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' If running on Microsoft Windows, the Chilkat mailman
' will automatically search the registry-based certificate stores
' for matching certificates and private keys required for
' decryption.  However, on Linux, MAX OS X, and other
' operating systems, no such thing exists.  Therefore, you'll 
' need to specify one or more PFX (.p12 / .pfx) files as
' sources for locating the certs required for decyrption.

success = mailman.AddPfxSourceFile("/pfxFiles/certs_and_keys_1.pfx","pfxPassword1")
If (success <> True) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

success = mailman.AddPfxSourceFile("/pfxFiles/certs_and_keys_2.pfx","pfxPassword2")
If (success <> True) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' ...
' Note: On MS Windows, it is not required to provide PFX sources
' if the needed certs and private keys are already installed
' on the system (in the registry-based certificate stores).

' Copy the all email from the user's POP3 mailbox 
' into a bundle object.  The email remains on the server.

Set bundle = mailman.CopyMail()
If (mailman.LastMethodSuccess = False) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' S/MIME security envelopes are automatically "unwrapped" 
' when a message is retrieved from the server. Signed emails are automatically verified, and 
' encrypted emails are automatically decrypted, restoring the email to the original state before 
' signing and/or encrypting. Information about the signing and encrypting certificates can be 
' retrieved from the Email object (methods: GetSignedByCert, GetEncryptedByCert; 
' properties: SignedBy, EncryptedBy, SignaturesValid, Decrypted, ReceivedSigned, 
' ReceivedEncrypted).

' Loop over the bundle, 

i = 0
Do While i < bundle.MessageCount

    Set email = bundle.GetEmail(i)

    Debug.Print email.From
    Debug.Print email.Subject

    ' At this point, if the email was signed and/or encrypted, it is already "unwrapped", i.e.
    ' the email is already decrypted and in a state as if it were never signed or encrypted.
    ' You may check to see if the email was received encrypted or signed, and if so,
    ' whether it was successfully unwrapped and who signed or encrypted it:
    If (email.ReceivedEncrypted = True) Then

        Debug.Print "This email was encrypted when received."
        If (email.Decrypted = True) Then
            Debug.Print "This email was successfully decrypted.  It was encrypted by:"
            Debug.Print email.EncryptedBy
        Else
            Debug.Print "This email was not decrypted."
        End If

    End If

    If (email.ReceivedSigned = True) Then

        Debug.Print "This email was signed when received."
        If (email.SignaturesValid = True) Then
            Debug.Print "The signature was verified.  It was signed by:"
            Debug.Print email.SignedBy
        Else
            Debug.Print "The signature verification failed."
        End If

    End If

    ' The email's body, HTML body, attachments, etc.
    ' are decrypted and available just like any non-encrypted email.

    Debug.Print "--"

    i = i + 1
Loop