(Excel) Sign Manifest File to Generate a Passbook .pkpass file

Demonstrates how to create a Passbook .pkpass archive by creating a signature of a manifest file and then zipping to a .pkpass archive.

Download Excel Class Modules Chilkat Excel Class Modules

' Note: Requires Chilkat v9.5.0.75 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' ---------------------------------------------------------------------------------------------
' Note: Chilkat also has the capability to do everything in-memory (no files would be involved).  
' See this example:  Sign Manifest File to Generate a Passbook .pkpass in Memory
' ---------------------------------------------------------------------------------------------

' First create the manifest.json

Dim manifest As Chilkat.JsonObject
Set manifest = Chilkat.NewJsonObject
Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

Dim zip As Chilkat.Zip
Set zip = Chilkat.NewZip
Dim success As Boolean
success = zip.NewZip("qa_data/p7s/pass-wallet/example.pkpass")
' Set the AppendFromDir property to prevent that relative paths from being stored in the .pkpass archive.
zip.AppendFromDir = "qa_data/p7s/pass-wallet/"

crypt.HashAlgorithm = "sha1"
' Return hashes as lowercase hex.
crypt.EncodingMode = "hexlower"

filePath = "qa_data/p7s/pass-wallet/icon.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("icon.png",False)
success = manifest.UpdateString("""icon.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/icon@2x.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("icon@2x.png",False)
success = manifest.UpdateString("""icon@2x.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/logo.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("logo.png",False)
success = manifest.UpdateString("""logo.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/logo@2x.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("logo@2x.png",False)
success = manifest.UpdateString("""logo@2x.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/pass.json"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("pass.json",False)
success = manifest.UpdateString("""pass.json""",fileHash)

Dim sbJson As Chilkat.StringBuilder
Set sbJson = Chilkat.NewStringBuilder
success = manifest.EmitSb(sbJson)

manifestPath = "qa_data/p7s/pass-wallet/manifest.json"
success = sbJson.WriteFile(manifestPath,"utf-8",False)
success = zip.AppendOneFileOrDir("manifest.json",False)

' Make sure we have the Apple WWDR intermediate certificate available for 
' the cert chain in the signature.
Dim certVault As Chilkat.XmlCertVault
Set certVault = Chilkat.NewXmlCertVault
Dim appleWwdrCert As Chilkat.Cert
Set appleWwdrCert = Chilkat.NewCert
success = appleWwdrCert.LoadByCommonName("Apple Worldwide Developer Relations Certification Authority")
If (success <> True) Then
    Debug.Print "The Apple WWDR intermediate certificate is not installed."
    Debug.Print "It is available at https://developer.apple.com/certificationauthority/AppleWWDRCA.cer"
    Debug.Print "You may alternatively load the .cer like this..."
    success = appleWwdrCert.LoadFromFile("qa_data/certs/AppleWWDRCA.cer")
    If (success <> True) Then
        Debug.Print appleWwdrCert.LastErrorText
        Exit Sub
    End If

End If

success = certVault.AddCert(appleWwdrCert)
success = crypt.UseCertVault(certVault)

' Use a digital certificate and private key from a PFX file (.pfx or .p12).

pfxPath = "qa_data/pfx/cert_test123.pfx"

pfxPassword = "test123"

Dim cert As Chilkat.Cert
Set cert = Chilkat.NewCert
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> True) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success <> True) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Specify the signed attributes to be included.
' (These attributes appear to not be necessary, but we're including
' them just in case they become necessary in the future.)
Dim jsonSignedAttrs As Chilkat.JsonObject
Set jsonSignedAttrs = Chilkat.NewJsonObject
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

' Sign the manifest JSON file to produce a file named "signature".

sigPath = "qa_data/p7s/pass-wallet/signature"

' Create the "signature" file.
success = crypt.CreateP7S(manifestPath,sigPath)
If (success = False) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

success = zip.AppendOneFileOrDir("signature",False)

' ---------------------------------------------------------------------------------------------
' Note: Chilkat also has the capability to do everything in-memory (no files would be involved).  
' If this is of interest, please send email to support@chilkatsoft.com
' ---------------------------------------------------------------------------------------------

' Create the .pkipass archive (which is a .zip archive containing the required files).
success = zip.WriteZipAndClose()
If (success <> True) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

Debug.Print "Success."