(Excel) Hungary NAV Manage Annulment Request

Demonstrates the manageAnnulment request for the Hungarian NAV Online Invoicing System REST API v2.0.

Note: This example requires Chilkat v9.5.0.83 or greater.

For more information, see https://onlineszamla.nav.gov.hu/api/files/container/download/Online%20Szamla_Interfesz%20specifik%C3%A1ci%C3%B3_EN_v2.0.pdf

Download Excel Class Modules Chilkat Excel Class Modules

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Build the following XML:

' Use this online tool to generate code from sample XML: 
' Generate Code to Create XML

' <?xml version="1.0" encoding="UTF-8"?>
' <ManageAnnulmentRequest xmlns="http://schemas.nav.gov.hu/OSA/2.0/api">
' 	<header>
' 		<requestId>RID338592103413</requestId>
' 		<timestamp>2019-09-11T13:37:09.385Z</timestamp>
' 		<requestVersion>2.0</requestVersion>
' 		<headerVersion>1.0</headerVersion>
' 	</header>
' 	<user>
' 		<login>lwilsmn0uqdxe6u</login>
' 		<passwordHash>2F43840A882CFDB7DB0 ... F6CA57FE8CD74DC28E</passwordHash>
' 		<taxNumber>11111111</taxNumber>
' 		<requestSignature>A297E3BD9 ... 1959ADFAF5</requestSignature>
' 	</user>
' 	<software>
' 		<softwareId>123456789123456789</softwareId>
' 		<softwareName>string</softwareName>
' 		<softwareOperation>LOCAL_SOFTWARE</softwareOperation>
' 		<softwareMainVersion>string</softwareMainVersion>
' 		<softwareDevName>string</softwareDevName>
' 		<softwareDevContact>string</softwareDevContact>
' 		<softwareDevCountryCode>HU</softwareDevCountryCode>
' 		<softwareDevTaxNumber>string</softwareDevTaxNumber>
' 	</software>
' 	<exchangeToken>dbd03076-3a9b-4312-bbbb-0cee3a6472572P11CS49ASIL</exchangeToken>
' 	<annulmentOperations>
' 		<annulmentOperation>
' 			<index>1</index>
' 			<annulmentOperation>ANNUL</annulmentOperation>
' 			<invoiceAnnulment>PD94bWwgdm ... ubnVsbWVudD4=</invoiceAnnulment>
' 		</annulmentOperation>
' 	</annulmentOperations>
' </ManageAnnulmentRequest>

Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

Dim dtNow As Chilkat.CkDateTime
Set dtNow = Chilkat.NewCkDateTime
Dim success As Boolean
success = dtNow.SetFromCurrentSystemTime()
Debug.Print dtNow.GetAsTimestamp(False)

' The hash algorithm for the password is SHA512 (not SHA3-512).
crypt.HashAlgorithm = "sha512"
crypt.EncodingMode = "hex"

myPassword = "my-password"

passwordHash = crypt.HashStringENC(myPassword)

' Generate a random request ID like "RID215118906689"
Dim prng As Chilkat.Prng
Set prng = Chilkat.NewPrng
Dim sbRequestId As Chilkat.StringBuilder
Set sbRequestId = Chilkat.NewStringBuilder
success = sbRequestId.Append("RID")
success = sbRequestId.Append(prng.RandomString(12,True,False,False))
Debug.Print "generated requestId = "; sbRequestId.GetAsString()

' Calculate the requestSignature
crypt.HashAlgorithm = "sha3-512"

signatureKey = "ce-8f5e-215119fa7dd621DLMRHRLH2S"

Dim sbFinalHashBase As Chilkat.StringBuilder
Set sbFinalHashBase = Chilkat.NewStringBuilder

' First append the timestamp because we are going to remove certain chars/parts.
success = sbFinalHashBase.Append(dtNow.GetAsTimestamp(False))

numReplaced = sbFinalHashBase.Replace("Z","")
numReplaced = sbFinalHashBase.Replace("-","")
numReplaced = sbFinalHashBase.Replace(":","")
numReplaced = sbFinalHashBase.Replace("T","")

' Prepend the requestId and append the signatureKey
success = sbFinalHashBase.Prepend(sbRequestId.GetAsString())
success = sbFinalHashBase.Append(signatureKey)

' Calculate first (and only) index hash.

invoiceOperation = "ANNUL"

invoiceData = "PD94bWwgdmVyc2lvbj0iMS4wIiBlbmNvZGluZz0iVVRGLTgiIHN0YW5kYWxvbmU9InllcyI/Pg0KPEludm9pY2VBbm51bG1lbnQgeG1sbnM9Imh0dHA6Ly9zY2hlbWFzLm5hdi5nb3YuaHUvT1NBLzIuMC9hbm51bCI+DQoJCTxhbm51bG1lbnRSZWZlcmVuY2U+MjIyMjIyMjI8L2FubnVsbWVudFJlZmVyZW5jZT4NCgkJPGFubnVsbWVudFRpbWVzdGFtcD4yMDE4LTA2LTE4VDA5OjEwOjQ1LjMwOVo8L2FubnVsbWVudFRpbWVzdGFtcD4NCgkJPGFubnVsbWVudENvZGU+RVJSQVRJQ19EQVRBPC9hbm51bG1lbnRDb2RlPg0KCQk8YW5udWxtZW50UmVhc29uPmNyZWF0ZSBzemFtbGEgYW5udWw8L2FubnVsbWVudFJlYXNvbj4NCjwvSW52b2ljZUFubnVsbWVudD4="

Dim sbHashBase As Chilkat.StringBuilder
Set sbHashBase = Chilkat.NewStringBuilder
success = sbHashBase.Append(invoiceOperation)
success = sbHashBase.Append(invoiceData)

firstHash = crypt.HashStringENC(sbHashBase.GetAsString())

' Append the index hash to the final hash base.
success = sbFinalHashBase.Append(firstHash)

' Get our request signature (using sha3-512 because our HashAlgorithm was set to "sha3-512" up above...)

requestSignature = crypt.HashStringENC(sbFinalHashBase.GetAsString())

' Load our recently obtained exchange token.
' See Hungary NAV Invoicing Token Exchange Sample Code
Dim xmlExchangeToken As Chilkat.Xml
Set xmlExchangeToken = Chilkat.NewXml
success = xmlExchangeToken.LoadXmlFile("qa_data/tokens/nav_exchange_token.xml")
If (success = False) Then
    Debug.Print xmlExchangeToken.LastErrorText
    Exit Sub
End If

' Get the base64 encoded/encrypted exchange token.
' IMPORTANT:  Make sure to use the exchange token before it expires.
' If it expired, then get a new one..

encodedEncryptedExchangeToken = xmlExchangeToken.GetChildContent("encodedExchangeToken")

' Decode to binary.
Dim bdExchangeToken As Chilkat.BinData
Set bdExchangeToken = Chilkat.NewBinData
success = bdExchangeToken.AppendEncoded(encodedEncryptedExchangeToken,"base64")

' Decrypt using your 16-digit replacement key:
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "ecb"
crypt.KeyLength = 128
crypt.EncodingMode = "base64"
' Pass your 16-digit replacement key here:
crypt.SetEncodedKey "99952BBAAAAA8XYZ","ascii"
success = crypt.DecryptBd(bdExchangeToken)

exchangeToken = bdExchangeToken.GetString("utf-8")
Debug.Print "exchange token = "; exchangeToken

' Now build the XML..
Dim xml As Chilkat.Xml
Set xml = Chilkat.NewXml
xml.Tag = "ManageAnnulmentRequest"
success = xml.AddAttribute("xmlns","http://schemas.nav.gov.hu/OSA/2.0/api")
xml.UpdateChildContent "header|requestId",sbRequestId.GetAsString()
xml.UpdateChildContent "header|timestamp",dtNow.GetAsTimestamp(False)
xml.UpdateChildContent "header|requestVersion","2.0"
xml.UpdateChildContent "header|headerVersion","1.0"
xml.UpdateChildContent "user|login","lwilsmn0uqdxe6u"
xml.UpdateChildContent "user|passwordHash",passwordHash
xml.UpdateChildContent "user|taxNumber","11111111"
xml.UpdateChildContent "user|requestSignature",requestSignature
xml.UpdateChildContent "software|softwareId","123456789123456789"
xml.UpdateChildContent "software|softwareName","string"
xml.UpdateChildContent "software|softwareOperation","LOCAL_SOFTWARE"
xml.UpdateChildContent "software|softwareMainVersion","string"
xml.UpdateChildContent "software|softwareDevName","string"
xml.UpdateChildContent "software|softwareDevContact","string"
xml.UpdateChildContent "software|softwareDevCountryCode","HU"
xml.UpdateChildContent "software|softwareDevTaxNumber","string"
xml.UpdateChildContent "exchangeToken",exchangeToken
xml.UpdateChildContent "annulmentOperations|annulmentOperation|index","1"
xml.UpdateChildContent "annulmentOperations|annulmentOperation|annulmentOperation",invoiceOperation
xml.UpdateChildContent "annulmentOperations|annulmentOperation|invoiceAnnulment",invoiceData

' POST the XML to https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/manageAnnulment
Dim http As Chilkat.Http
Set http = Chilkat.NewHttp
http.Accept = "application/xml"
http.SetRequestHeader "Content-Type","application/xml"

endpoint = "https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/manageAnnulment"

Set resp = http.PostXml(endpoint,xml.GetXml(),"utf-8")
If (http.LastMethodSuccess = False) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response status code = "; resp.StatusCode

Dim respXml As Chilkat.Xml
Set respXml = Chilkat.NewXml
success = respXml.LoadXml(resp.BodyStr)
Debug.Print "Response body:"
Debug.Print respXml.GetXml()

' The result looks like this:

' <?xml version="1.0" encoding="UTF-8" standalone="yes"?>
' <ManageAnnulmentResponse xmlns="http://schemas.nav.gov.hu/OSA/2.0/api" xmlns:ns2="http://schemas.nav.gov.hu/OSA/2.0/data">
'     <header>
'         <requestId>RID465317110495</requestId>
'         <timestamp>2020-03-25T15:08:40Z</timestamp>
'         <requestVersion>2.0</requestVersion>
'         <headerVersion>1.0</headerVersion>
'     </header>
'     <result>
'         <funcCode>OK</funcCode>
'     </result>
'     <software>
'         <softwareId>123456789123456789</softwareId>
'         <softwareName>string</softwareName>
'         <softwareOperation>LOCAL_SOFTWARE</softwareOperation>
'         <softwareMainVersion>string</softwareMainVersion>
'         <softwareDevName>string</softwareDevName>
'         <softwareDevContact>string</softwareDevContact>
'         <softwareDevCountryCode>HU</softwareDevCountryCode>
'         <softwareDevTaxNumber>string</softwareDevTaxNumber>
'     </software>
'     <transactionId>2WT6XG9LQ0U9VQNA</transactionId>
' </ManageAnnulmentResponse>

' Use this online tool to generate parsing code from sample XML: 
' Generate Parsing Code from XML


ManageAnnulmentResponse_xmlns = respXml.GetAttrValue("xmlns")

ManageAnnulmentResponse_xmlns_ns2 = respXml.GetAttrValue("xmlns:ns2")

requestId = respXml.GetChildContent("header|requestId")

timestamp = respXml.GetChildContent("header|timestamp")

requestVersion = respXml.GetChildContent("header|requestVersion")

headerVersion = respXml.GetChildContent("header|headerVersion")

funcCode = respXml.GetChildContent("result|funcCode")

softwareId = respXml.GetChildContent("software|softwareId")

softwareName = respXml.GetChildContent("software|softwareName")

softwareOperation = respXml.GetChildContent("software|softwareOperation")

softwareMainVersion = respXml.GetChildContent("software|softwareMainVersion")

softwareDevName = respXml.GetChildContent("software|softwareDevName")

softwareDevContact = respXml.GetChildContent("software|softwareDevContact")

softwareDevCountryCode = respXml.GetChildContent("software|softwareDevCountryCode")

softwareDevTaxNumber = respXml.GetChildContent("software|softwareDevTaxNumber")

transactionId = respXml.GetChildContent("transactionId")