(Excel) Microsoft Graph Calendar OAuth2 Access Token

Demonstrates how to get a Microsoft Graph OAuth2 access token from a desktop application or script. This example uses the Azure AD v2.0 Endpoint.

The Microsoft Graph supports two authentication providers:

• To authenticate users with personal Microsoft accounts, such as live.com or outlook.com accounts, use the Azure Active Directory (Azure AD) v2.0 endpoint.
• To authenticate users with enterprise (that is, work or school) accounts, use Azure AD.

This example uses the Azure Active Directory (Azure AD) v2.0 endpoint.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim oauth2 As Chilkat.OAuth2
Set oauth2 = Chilkat.NewOAuth2

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
oauth2.TokenEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

' Replace these with actual values.
oauth2.ClientId = "MICROSOFT-GRAPH-CLIENT-ID"
' This is your app password:
oauth2.ClientSecret = "MICROSOFT-GRAPH-CLIENT-SECRET"

oauth2.CodeChallenge = False
' Provide a SPACE separated list of scopes.
' See https://developer.microsoft.com/en-us/graph/docs/authorization/permission_scopes 

' Important: To get a refresh token in the final response, you must include the "offline_access" scope
oauth2.Scope = "openid profile offline_access user.readwrite calendars.readwrite files.readwrite"

' Begin the OAuth2 three-legged flow.  This returns a URL that should be loaded in a browser.

url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> True) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' At this point, your application should load the URL in a browser.
' For example, 
' in C#: System.Diagnostics.Process.Start(url);
' in Java: Desktop.getDesktop().browse(new URI(url));
' in VBScript: Set wsh=WScript.CreateObject("WScript.Shell")
'              wsh.Run url
' in Xojo: ShowURL(url)  (see http://docs.xojo.com/index.php/ShowURL)
' in Dataflex: Runprogram Background "c:\Program Files\Internet Explorer\iexplore.exe" sUrl        
' The Microsoft account owner would interactively accept or deny the authorization request.

' Add the code to load the url in a web browser here...
' Add the code to load the url in a web browser here...
' Add the code to load the url in a web browser here...

' Now wait for the authorization.
' We'll wait for a max of 30 seconds.

numMsWaited = 0
Do While (numMsWaited < 30000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If there was no response from the browser within 30 seconds, then 
' the AuthFlowState will be equal to 1 or 2.
' 1: Waiting for Redirect. The OAuth2 background thread is waiting to receive the redirect HTTP request from the browser.
' 2: Waiting for Final Response. The OAuth2 background thread is waiting for the final access token response.
' In that case, cancel the background task started in the call to StartAuth.
If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check the AuthFlowState to see if authorization was granted, denied, or if some error occurred
' The possible AuthFlowState values are:
' 3: Completed with Success. The OAuth2 flow has completed, the background thread exited, and the successful JSON response is available in AccessTokenResponse property.
' 4: Completed with Access Denied. The OAuth2 flow has completed, the background thread exited, and the error JSON is available in AccessTokenResponse property.
' 5: Failed Prior to Completion. The OAuth2 flow failed to complete, the background thread exited, and the error information is available in the FailureInfo property.
If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:"; oauth2.AuthFlowState
    Exit Sub
End If

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = "; oauth2.AccessToken

' Get the full JSON response:
Dim json As Chilkat.JsonObject
Set json = Chilkat.NewJsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = False

' The JSON response looks like this:

' {
'   "token_type": "Bearer",
'   "scope": "openid profile User.ReadWrite Calendars.ReadWrite Files.ReadWrite User.Read",
'   "expires_in": 3600,
'   "ext_expires_in": 0,
'   "access_token": "EwBAA8l6B...",
'   "refresh_token": "MCRMdbe...",
'   "id_token": "eyJ0eXA..."
' }

' If an "expires_on" member does not exist, then add the JSON member by
' getting the current system date/time and adding the "expires_in" seconds.
' This way we'll know when the token expires.
If (json.HasMember("expires_on") <> True) Then
    Dim dtExpire As Chilkat.CkDateTime
    Set dtExpire = Chilkat.NewCkDateTime
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(json.IntOf("expires_in"))
    success = json.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(False))
End If

Debug.Print json.Emit()

' Save the JSON to a file for future requests.
Dim fac As Chilkat.FileAccess
Set fac = Chilkat.NewFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/msGraphCalendar.json",json.Emit(),"utf-8",False)