(Excel) JWE using "dir" Direct use of Shared Symmetric Key

Demonstrates how to create a JWE using the "dir" alg -- which is to directly use a shared symmetric key.

Note: This example requires Chilkat v9.5.0.66 or greater.

Download Excel Class Modules Chilkat Excel Class Modules

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.


plaintext = "Live long and prosper."

Dim jwe As Chilkat.Jwe
Set jwe = Chilkat.NewJwe

' First build the JWE Protected Header..
Dim jweProtHdr As Chilkat.JsonObject
Set jweProtHdr = Chilkat.NewJsonObject
Dim success As Boolean
success = jweProtHdr.AppendString("alg","dir")
success = jweProtHdr.AppendString("enc","A128GCM")

' Don't forget to actually provide the protected header to the JWE object:
success = jwe.SetProtectedHeader(jweProtHdr)

' The JWE is to use 128-bit AES GCM encryption as specified by the "enc" parameter.
' Given that the "alg" = "dir", we are to directly specify the AES GCM key.
' (It is assumed that the decrypting side also has knowledge of the direct key to be used..)

' Our key will be these 16 hex bytes: 000102030405060708090A0B0C0D0E0F

' The SetWrappingKey method is also used for "dir" direct keys.
' However, if there are multiple recipients, they must all share the same CEK (Content Encryption Key),
' which is specified by calling SetWrappingKey with an index of 0.


recipientIndex = 0
success = jwe.SetWrappingKey(recipientIndex,"000102030405060708090A0B0C0D0E0F","hex")

' Encrypt and return the JWE:

strJwe = jwe.Encrypt(plaintext,"utf-8")
If (jwe.LastMethodSuccess <> True) Then
    Debug.Print jwe.LastErrorText
    Exit Sub
End If

' Show the JWE we just created:
Debug.Print strJwe

' Decrypt the JWE.
Dim jwe2 As Chilkat.Jwe
Set jwe2 = Chilkat.NewJwe
success = jwe2.LoadJwe(strJwe)
If (success <> True) Then
    Debug.Print jwe2.LastErrorText
    Exit Sub
End If

success = jwe2.SetWrappingKey(0,"000102030405060708090A0B0C0D0E0F","hex")

' Decrypt.

originalPlaintext = jwe2.Decrypt(0,"utf-8")
If (jwe2.LastMethodSuccess <> True) Then
    Debug.Print jwe2.LastErrorText
    Exit Sub
End If

Debug.Print "original text: "
Debug.Print originalPlaintext

' Sample output:
' eyJhbGciOiJkaXIiLCJlbmMiOiJBMTI4R0NNIn0..20HX5Huc7f1nQC4pBUtiCQ.axFZIxtZy5j0ifJQUzGXLKIpsBuxJA.eBrOC-NrsreN6JeGuOPk1g
' original text: 
' Live long and prosper.