(Excel) IMAP Get Quota

Sends the GETQUOTA command to the IMAP server to get the quota information for a given quota root.

The GetQuota method is available in Chilkat starting at v9.5.0.58, and is only available for IMAP servers that support the QUOTA extension.

The information is returned in JSON format. This example demonstrates how to parse the JSON to get the desired information.

Typically, the quota root for the Inbox is the empty string. The GetQuotaRoot method can be called to get the quota root for a given mailbox.

Download Excel Class Modules Chilkat Excel Class Modules

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As Chilkat.Imap
Set imap = Chilkat.NewImap

' Use TLS
imap.Ssl = True
imap.Port = 993

success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> True) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Authenticate
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> True) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' First check to see if the IMAP server supports the QUOTA extension.

caps = imap.Capability()
If (imap.LastMethodSuccess <> True) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

If (imap.HasCapability("QUOTA",caps) <> True) Then
    Debug.Print "IMAP server does not support the QUOTA extension."
    Exit Sub
End If

' This example assumes we already know the quota root for the given mailbox.
' For Inbox, it is typically the empty string.  See the documentation and example 
' for the GetQuotaRoot method to query for the quota root of a mailbox.  
' (It's probably easier to use GetQuotaRoot because the mailbox name
' can be passed to it, and in addition, it returns the quota information.)
' method for details 

jsonStr = imap.GetQuota("")
If (imap.LastMethodSuccess <> True) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The JSON string will look something like this:
' {"QUOTA":{"root":"","resource":"STORAGE","used":22216,"max":15728640}}
Debug.Print jsonStr

' This is easy to parse...
Dim json As Chilkat.JsonObject
Set json = Chilkat.NewJsonObject
success = json.Load(jsonStr)

' Now get the resource name (which can be STORAGE or MESSAGE) and the used/max values.
' Most servers have STORAGE quotas, which are for total capacity.  For example, GMail's
' STORAGE quota is 15GB (at the time of writing this example).
' A MESSAGE quota sets a limit on the number of messages.

resourceName = json.StringOf("QUOTA.resource")

quotaUsed = json.IntOf("QUOTA.used")

quotaMax = json.IntOf("QUOTA.max")

Debug.Print "Resource: "; resourceName
Debug.Print "Quota Used (in KB): "; quotaUsed
Debug.Print "Quota Max (in KB): "; quotaMax

' Disconnect from the IMAP server.
success = imap.Disconnect()