(Excel) Use a Custom Set of Trusted Root Certificates

Demonstrates how to build a set of trusted root certificates to be used globally by all Chilkat classes.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim trustedRoots As Chilkat.TrustedRoots
Set trustedRoots = Chilkat.NewTrustedRoots

'  Indicate that we will NOT trust any pre-installed certificates on the system.
trustedRoots.TrustSystemCaRoots = False

' Thawte is a certificate authority that provides a .zip download of their
' root CA certificates:  https://www.thawte.com/roots/index.html
' The direct download link is: https://www.verisign.com/support/thawte-roots.zip
' Note: The above URLs are valid at the time of writing this example (29-May-2015).

' Assuming the .zip has already been downloaded, open it and load each .pem file into
' our trusted roots object.
Dim zip As Chilkat.Zip
Set zip = Chilkat.NewZip

' Open a .zip containing PEM files, among other things..

success = zip.OpenZip("qa_data/certs/thawte-roots.zip")
If (success <> True) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If


Set entry = zip.FirstMatchingEntry("*.pem")
If (zip.LastMethodSuccess <> True) Then
    Debug.Print "No entries matched."
    Exit Sub
End If

Dim cert As Chilkat.Cert
Set cert = Chilkat.NewCert


bHasMoreEntries = True
Do While (bHasMoreEntries = True)

    Debug.Print "Entry: "; entry.FileName

    ' Get the PEM of the CA cert:
    pemStr = entry.UnzipToString(0,"utf-8")

    ' Load it into a certificate object:
    success = cert.LoadPem(pemStr)
    If (success <> True) Then
        Debug.Print cert.LastErrorText
    End If

    ' Add it to the trusted roots.
    success = trustedRoots.AddCert(cert)

    ' The NextMatchingEntry method was added in v9.5.0.50
    Set nextEntry = entry.NextMatchingEntry("*.pem")
    bHasMoreEntries = entry.LastMethodSuccess

    Set entry = nextEntry
Loop

'  Activate the trusted roots globally for all Chilkat objects.
'  This call really shouldn't fail, so we're not checking the return value.
success = trustedRoots.Activate()