(Excel) Generate ECDSA Key and Get Details as XML

Demonstrates how to generate an ECC key and gets the parts as XML.

Download Excel Class Modules Chilkat Excel Class Modules

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ecc As Chilkat.Ecc
Set ecc = Chilkat.NewEcc

'  Generate a random ECC private key on the secp256k1 curve.
'  Chilkat also supports other curves, such as secp384r1, secp521r1, and secp256r1.

'  Create a Fortuna PRNG and seed it with system entropy.
'  This will be our source of random data for generating the ECC private key.
Dim fortuna As Chilkat.Prng
Set fortuna = Chilkat.NewPrng

entropy = fortuna.GetEntropy(32,"base64")

success = fortuna.AddEntropy(entropy,"base64")


Set privKey = ecc.GenEccKey("secp256k1",fortuna)
If (ecc.LastMethodSuccess <> True) Then
    Debug.Print ecc.LastErrorText
    Exit Sub
End If

'  An EC private key has this ASN.1
'  ECPrivateKey ::= SEQUENCE {
'      version        INTEGER { ecPrivkeyVer1(1) } (ecPrivkeyVer1),
'      privateKey     OCTET STRING,
'      parameters [0] ECParameters {{ NamedCurve }} OPTIONAL,
'      publicKey  [1] BIT STRING OPTIONAL (This is the ANSI X9.63 public key format.)

Dim asn As Chilkat.Asn
Set asn = Chilkat.NewAsn
success = asn.LoadEncoded(privKey.GetPkcs1ENC("base64"),"base64")
If (success <> True) Then
    Debug.Print asn.LastErrorText
    Exit Sub
End If

Dim xml As Chilkat.Xml
Set xml = Chilkat.NewXml
success = xml.LoadXml(asn.AsnToXml())

Debug.Print xml.GetXml()

'  The XML looks like this:
'  <?xml version="1.0" encoding="utf-8" ?>
'  <sequence>
'      <int>01</int>
'      <octets>JgJvBG+3wletkJab8iXAkpz0O8/AgWZSpkYVcB7SpnU=</octets>
'      <contextSpecific tag="0" constructed="1">
'          <oid>1.3.132.0.10</oid>
'      </contextSpecific>
'  </sequence>

'  The 32-byte private key is in the octets..
'  Get it as hex.
Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

privKeyHex = crypt.ReEncode(xml.GetChildContent("octets"),"base64","hex")

Debug.Print "EC private key as hex = "; privKeyHex