(Excel) Sign String to create a CAdES-T Signature

This example will sign a string to create a CAdEST-T signature.

Note: This example requires Chilkat v9.5.0.78 or greater.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

' This example will use the certificate + private key currently inserted into a smartcard reader.
Dim cert As Chilkat.Cert
Set cert = Chilkat.NewCert

' If we wish to provide the smartcard PIN (otherwise the user will be prompted by the operating system).
cert.SmartCardPin = "000000"

success = cert.LoadFromSmartcard("")
If (success <> True) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Note: It is also possible to use certs from .pfx/.p12, .pem, or other sources such as 
' pre-installed Windows certificates.

success = crypt.SetSigningCert(cert)

' Use SHA-256 rather than the default of SHA-1
crypt.HashAlgorithm = "sha256"

' Create JSON that tells Chilkat what signing attributes to include:
Dim attrs As Chilkat.JsonObject
Set attrs = Chilkat.NewJsonObject
success = attrs.UpdateBool("contentType",True)
success = attrs.UpdateBool("signingTime",True)
success = attrs.UpdateBool("messageDigest",True)
success = attrs.UpdateBool("signingCertificateV2",True)

' A CAdES-T signature is one that includes a timestampToken created by an online TSA (time stamping authority).
' We must include the TSA's URL, as well as a few options to indicate what is desired.
' Except for the TSA URL, the options shown here are typically what you would need.
success = attrs.UpdateBool("timestampToken.enabled",True)
success = attrs.UpdateString("timestampToken.tsaUrl","https://freetsa.org/tsr")
success = attrs.UpdateBool("timestampToken.addNonce",False)
success = attrs.UpdateBool("timestampToken.requestTsaCert",True)
success = attrs.UpdateString("timestampToken.hashAlg","sha256")

crypt.SigningAttributes = attrs.Emit()


strToSign = "THIS IS MY ID"

Dim bd As Chilkat.BinData
Set bd = Chilkat.NewBinData
success = bd.AppendString(strToSign,"utf-8")

' This creates the CAdES-T signature.  During the signature creation, it
' communicates with the TSA to get a timestampToken.
' The contents of bd are signed and replaced with the CAdES-T signature (which embeds the original content).
success = crypt.OpaqueSignBd(bd)
If (success <> True) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Get the signature in base64 format:
Debug.Print bd.GetEncoded("base64_mime")

' Or save the signature to a file.
success = bd.WriteFile("qa_output/cades-t_sample.p7m")

Debug.Print "Success."