(Excel) Encrypting/decrypting a data stream.

This example demonstrates how to encrypt (using a symmetric encryption algorithm such as AES, ChaCha20, Blowfish, RC2, 3DES, etc) a large amount of data. The data is passed in chunks to one of the encrypt methods: EncryptBytes, EncryptString, EncryptBytesENC, or EncryptStringENC, etc. The FirstChunk and LastChunk properties are used to indicate whether a chunk is the first, middle, or last in a stream to be encrypted. By default, both FirstChunk and LastChunk equal True -- meaning that the data passed is the entire amount.

Note: You may feed the data in chunks that are smaller than the block size of the encryption algorithm (AES and Twofish have a block size of 16 bytes. DES, 3DES, Blowfish, and RC2 have a block size of 8 bytes. ARC4 and ChaCha20 are streaming encryption algorithms and don't have a block size, but technically you can think of it as having a block size of 1 byte.)

Chilkat will buffer the data as required. If an amount of data smaller than the block size is passed such that the entire amount is buffered, then an empty string (or 0 bytes) is returned. The buffered data will be added to the data passed in subsequent calls. When the final data chunk is passed, it is padded to the encryption algorithm's block size (according to the PaddingScheme property) and the encryption is complete.

Decrypting in chunks is identical to encrypting in chunks.

Download Excel Class Modules Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

crypt.EncodingMode = "hex"

txt1 = "The quick brown fox jumped over the lazy dog." & vbCrLf

txt2 = "-" & vbCrLf

txt3 = "Done." & vbCrLf

Dim sbEncrypted As Chilkat.StringBuilder
Set sbEncrypted = Chilkat.NewStringBuilder

' Encrypt the 1st chunk:
' (don't worry about feeding the data to the encryptor in 
' exact multiples of the encryption algorithm's block size.
' Chilkat will buffer the data.)
crypt.FirstChunk = True
crypt.LastChunk = False
Dim success As Boolean
success = sbEncrypted.Append(crypt.EncryptStringENC(txt1))

' Encrypt the 2nd chunk
crypt.FirstChunk = False
crypt.LastChunk = False
success = sbEncrypted.Append(crypt.EncryptStringENC(txt2))

' Now encrypt N more chunks...
' Remember -- we're doing this in CBC mode, so each call
' to the encrypt method depends on the state from previous
' calls...
crypt.FirstChunk = False
crypt.LastChunk = False

For i = 0 To 4
    success = sbEncrypted.Append(crypt.EncryptStringENC(txt1))
    success = sbEncrypted.Append(crypt.EncryptStringENC(txt2))
Next

' Now encrypt the last chunk:
crypt.FirstChunk = False
crypt.LastChunk = True
success = sbEncrypted.Append(crypt.EncryptStringENC(txt3))

Debug.Print sbEncrypted.GetAsString()

' Now decrypt in one call.
' (The data we're decrypting is both the first AND last chunk.)  
crypt.FirstChunk = True
crypt.LastChunk = True

decryptedText = crypt.DecryptStringENC(sbEncrypted.GetAsString())

Debug.Print decryptedText

' Note: You may decrypt in N chunks by setting the FirstChunk
' and LastChunk properties prior to calling the Decrypt* methods