(Delphi ActiveX) Cancel Async Task if not Completed after a Max Time

Demonstrates how to wait a maximum amount of time for an asynchronous task to completed. If not completed in the allotted amount of time, the task is cancelled.

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
success: Integer;
http: TChilkatHttp;
waitMaxMs: Integer;
downloadUrl: WideString;
task: IChilkatTask;
wasCanceled: Integer;

begin
// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

http := TChilkatHttp.Create(Self);

// Set some timeouts, in seconds:
http.ConnectTimeout := 15;
http.ReadTimeout := 15;

// Wait a max time of 2 seconds for the task.
// In this example, it's an unreasonably small amount of time,
// which means the task will get cancelled.
waitMaxMs := 2000;

// We're just going to download for 2 seconds and then cancel.
// Substitute your own URL with a large enough file for testing..
downloadUrl := 'http://download.mono-project.com/archive/4.6.1/windows-installer/mono-4.6.1.5-gtksharp-2.12.38-win32-0.msi';

task := http.DownloadAsync(downloadUrl,'qa_output/mono.msi');
task.Run();

// Wait a maximum of waitMaxMs for the task (i.e. the HTTP download) to complete.
// The Wait method returns when the task has been canceled, aborted, or completed, or when the max allotted time has passed.
task.Wait(waitMaxMs);

// At this point, the download may or may not have completed.  
// Rather than checking the Task status, we can call task.Cancel because
// if the Task is no longer running (because it already completed, was canceled or aborted), then the 
// call to Cancel is a NO-OP (meaning it does nothing and the Task's status is unaffected).
// Also, task.Cancel returns 1 if the task was in the "queued" or "running" state and was canceled or aborted. 
// The method returns 0 if the task has any other status.
wasCanceled := task.Cancel();
if (wasCanceled = 1) then
  begin
    Memo1.Lines.Add('The HTTP download took too long and was canceled.');
  end
else
  begin
    // Find out what happened.
    if (task.StatusInt = 7) then
      begin
        // The task completed, which means the background thread's call to Download completed
        // with success or failure.  Find out which...
        success := task.GetResultBool();
        if (success = 1) then
          begin
            Memo1.Lines.Add('Download successful!');
          end
        else
          begin
            Memo1.Lines.Add('Download failed prior to waitMaxMs...');
            Memo1.Lines.Add(task.ResultErrorText);
          end;
      end
    else
      begin
        // The task must've been canceled or aborted by some other means..
        Memo1.Lines.Add('Task did not complete.  Final status: ' + task.Status);
      end;
  end;
end;