(Delphi ActiveX) ZATCA QR Code TLV Encoding and ECDSA Cryptographic Stamp

See more ZATCA Examples

Demonstrates how to create the TLV encoding of the QR code fields, then apply the ECDSA signature and ECDSA public key, and finally insert into the previously signed XML E-Invoice.

Note: This example requires Chilkat v9.5.0.92 or greater.

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
success: Integer;
sellerName: WideString;
vatNumber: WideString;
dt: TCkDateTime;
timeStamp: WideString;
invoiceTotal: WideString;
vatTotal: WideString;
bdTlv: TChilkatBinData;
charset: WideString;
tag: Integer;
signedXmlFilePath: WideString;
xmlSigned: TChilkatXml;
sbDigestValue: TChilkatStringBuilder;
sbSignatureValue: TChilkatStringBuilder;
x509Certificate: WideString;
cert: TChilkatCert;
bdPubKey: TChilkatBinData;
bdCertSig: TChilkatBinData;
qr_base64: WideString;
xmlQR: TChilkatXml;
sbSignedXml: TChilkatStringBuilder;
sbReplaceStr: TChilkatStringBuilder;
verifier: TChilkatXmlDSig;
numSigs: Integer;
verifyIdx: Integer;
verified: Integer;

begin
// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// In Step 1, we applied a signature to an e-invoice Zakat, Tax and Customs Authority (ZATCA) of Saudi Arabia

// This example is Step 2, where we compose the TLV encoding of the QR code, apply the ECDSA signature, and then insert into the signed XML without disturbing the signed XML.

// Construct TLV (Tag-Length-Value) encoding of the QR data.
// We have 5 pieces of data: Seller Name, VAT Number, Time Stamp, Invoice Total, and VAT Total.
// For example:
sellerName := 'Firoz Ashraf';
vatNumber := '1234567891';

// The timestamp in QR Code should be based on Invoice Issue Time (KSA-25) and Invoice Issue Date (BT-2). 
// It can either be in format YYYY-MM-DD'T'HH:MM:SS (for local time in KSA) or YYYY-MM-DD'T'HH:MM:SS'Z' (for UTC time or Zulu time)

// Get the current UTC date/time in this format: YYYY-MM-DD'T'HH:MM:SS'Z'
dt := TCkDateTime.Create(Self);
dt.SetFromCurrentSystemTime();
timeStamp := dt.GetAsTimestamp(0);
invoiceTotal := '100.00';
vatTotal := '15.00';

// TLV encode into a Chilkat BinData object.
bdTlv := TChilkatBinData.Create(Self);

charset := 'utf-8';

tag := 1;
bdTlv.AppendByte(tag);
bdTlv.AppendCountedString(1,0,sellerName,charset);
tag := tag + 1;
// This is tag 2
bdTlv.AppendByte(tag);
bdTlv.AppendCountedString(1,0,vatNumber,charset);
tag := tag + 1;
// This is tag 3
bdTlv.AppendByte(tag);
bdTlv.AppendCountedString(1,0,timeStamp,charset);
tag := tag + 1;
// This is tag 4
bdTlv.AppendByte(tag);
bdTlv.AppendCountedString(1,0,invoiceTotal,charset);
tag := tag + 1;
// This is tag 5
bdTlv.AppendByte(tag);
bdTlv.AppendCountedString(1,0,vatTotal,charset);

// ----------------------------------------------------------------------------------------------------------------------------------------------
// For tag 6, we need the SHA256 hash from the signed XML.  This is the DigestValue as shown in the fragment of the XML Signature below:

//     <ds:Reference Id="invoiceSignedData" URI="">
//         <ds:Transforms>
//             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
//                 <ds:XPath>not(//ancestor-or-self::ext:UBLExtensions)</ds:XPath>
//             </ds:Transform>
//             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
//                 <ds:XPath>not(//ancestor-or-self::cac:Signature)</ds:XPath>
//             </ds:Transform>
//             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
//                 <ds:XPath>not(//ancestor-or-self::cac:AdditionalDocumentReference[cbc:ID='QR'])</ds:XPath>
//             </ds:Transform>
//             <ds:Transform Algorithm="http://www.w3.org/2006/12/xml-c14n11"/>
//         </ds:Transforms>
//         <ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/>
//         <ds:DigestValue>zCp+kF1qzNgXD6AhLq69/CYCklMFSXUmmVPbm4v/76U=</ds:DigestValue>
//     </ds:Reference>

// To get this information, we'll need to load the signed XML into a Chilkat XML object, and then access it.
// Load the XML we previously signed...
signedXmlFilePath := 'qa_data/zatca/testing/SignedXML.xml';
xmlSigned := TChilkatXml.Create(Self);
success := xmlSigned.LoadXmlFile(signedXmlFilePath);
if (success = 0) then
  begin
    Memo1.Lines.Add(xmlSigned.LastErrorText);
    Exit;
  end;

// digestValue is a base64 string.
sbDigestValue := TChilkatStringBuilder.Create(Self);
success := xmlSigned.GetChildContentSb('ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:SignedInfo|ds:Reference[0]|ds:DigestValue',sbDigestValue.ControlInterface);
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to get DigestValue from signed XML.');
    Exit;
  end;

Memo1.Lines.Add('DigestValue = ' + sbDigestValue.GetAsString());

// Append the DigestValue base64 string to the TLV.
tag := 6;
bdTlv.AppendByte(tag);
bdTlv.AppendByte(sbDigestValue.Length);
bdTlv.AppendSb(sbDigestValue.ControlInterface,'utf-8');

// ----------------------------------------------------------------------------------------------------------------------------------------------
// Tag 7 will contain the <ds:Signature> value from the signed XML.
// PS> To get the XML path passed to GetChildContentSb, you can copy/paste the signed XML into Chilkat's online tool at https://tools.chilkat.io/xmlParse
// The parsing code that is generated by the online tool will reveal the required path to the element in the XML.
sbSignatureValue := TChilkatStringBuilder.Create(Self);
success := xmlSigned.GetChildContentSb('ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:SignatureValue',sbSignatureValue.ControlInterface);
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to get SignatureValue from signed XML.');
    Exit;
  end;

Memo1.Lines.Add('SignatureValue = ' + sbSignatureValue.GetAsString());

// Append the SignatureValue base64 string to the TLV.
tag := 7;
bdTlv.AppendByte(tag);
bdTlv.AppendByte(sbSignatureValue.Length);
bdTlv.AppendSb(sbSignatureValue.ControlInterface,'utf-8');

// ----------------------------------------------------------------------------------------------------------------------------------------------
// Tag 8 will contain the public key of the signing certificate.
// The signing certificate is available within the signed XML at <ds:X509Certificate>.
x509Certificate := xmlSigned.GetChildContent('ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:KeyInfo|ds:X509Data|ds:X509Certificate');
if (xmlSigned.LastMethodSuccess = 0) then
  begin
    Memo1.Lines.Add('Failed to get X509Certificate from the signed XML.');
    Exit;
  end;

cert := TChilkatCert.Create(Self);
success := cert.SetFromEncoded(x509Certificate);
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to load signing certificate from base64.');
    Exit;
  end;

// We want to get the cert's public key bytes having this ASN.1 format.
// SEQUENCE (2 elem)
//   SEQUENCE (2 elem)
//     OBJECT IDENTIFIER 1.2.840.10045.2.1 ecPublicKey (ANSI X9.62 public key type)
//     OBJECT IDENTIFIER 1.3.132.0.10 secp256k1 (SECG (Certicom) named elliptic curve)
//   BIT STRING (520 bit) 0000010001110000110111000001111110100110101110110101111000110001110100

// Note: The cert.GetPubKeyDer method was added in Chilkat v9.5.0.92
bdPubKey := TChilkatBinData.Create(Self);
success := cert.GetPubKeyDer(1,bdPubKey.ControlInterface);
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to get certificate''s public key.');
    Exit;
  end;

// We want to add the binary bytes of the public key (not the base64 string) to the QR code.
tag := 8;
bdTlv.AppendByte(tag);
bdTlv.AppendByte(bdPubKey.NumBytes);
bdTlv.AppendBd(bdPubKey.ControlInterface);

// Show the public key in base64 format:
Memo1.Lines.Add('Certificate public key:');
Memo1.Lines.Add(bdPubKey.GetEncoded('base64'));

// ----------------------------------------------------------------------------------------------------------------------------------------------
// Tag 9 will contain the signature contained in the signing certificate.

// Note: The cert.GetPubKeyDer method was added in Chilkat v9.5.0.92
bdCertSig := TChilkatBinData.Create(Self);
success := cert.GetSignature(bdCertSig.ControlInterface);
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to get certificate''s signature.');
    Exit;
  end;

// We want to add the binary bytes of the signature (not the base64 string) to the QR code.
tag := 9;
bdTlv.AppendByte(tag);
bdTlv.AppendByte(bdCertSig.NumBytes);
bdTlv.AppendBd(bdCertSig.ControlInterface);

// Show the cert's signature in hex format:
Memo1.Lines.Add('Certificate signature:');
Memo1.Lines.Add(bdCertSig.GetEncoded('hex'));

// ----------------------------------------------------------------------------------------------------------------------------------------------
// At this point the full QR code is contained in bdTlv.
// Get it as a base64 string
qr_base64 := bdTlv.GetEncoded('base64');
Memo1.Lines.Add('QR: ' + qr_base64);

// ----------------------------------------------------------------------------------------------------------------------------------------------
// Insert the QR XML fragment into the previously signed XML -- without disturbing (invalidating) the signature.

// We need to build and insert the following XML fragment under the 
// as a cac:AdditionalDocumentReference just before the "<cac:Signature>" opening tag.

//    <cac:AdditionalDocumentReference>
//         <cbc:ID>QR</cbc:ID>
//         <cac:Attachment>
//             <cbc:EmbeddedDocumentBinaryObject mimeCode="text/plain">BASE64_TLV_CONTENT</cbc:EmbeddedDocumentBinaryObject>
//         </cac:Attachment>
//    </cac:AdditionalDocumentReference>

xmlQR := TChilkatXml.Create(Self);
xmlQR.Tag := 'cac:AdditionalDocumentReference';
xmlQR.UpdateChildContent('cbc:ID','QR');
xmlQR.UpdateAttrAt('cac:Attachment|cbc:EmbeddedDocumentBinaryObject',1,'mimeCode','text/plain');
xmlQR.UpdateChildContent('cac:Attachment|cbc:EmbeddedDocumentBinaryObject',bdTlv.GetEncoded('base64'));

// Load our previously signed XML into a Chilkat StringBuilder.
// We should not load the previously signed XML into a Chilkat XML object because the XML gets loaded into an internal DOM (Document Object Model).
// When re-emitted from the DOM, formatting can change and it would break the XML signature.
// Therefore, we must load into a StringBuilder and insert the new fragment without disturbing the remainder.
// The inserted fragment is ignored because the following transform was included in the XML signature reference:

//             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
//                 <ds:XPath>not(//ancestor-or-self::cac:AdditionalDocumentReference[cbc:ID='QR'])</ds:XPath>
//             </ds:Transform>

sbSignedXml := TChilkatStringBuilder.Create(Self);
success := sbSignedXml.LoadFile(signedXmlFilePath,'utf-8');
if (success = 0) then
  begin
    Memo1.Lines.Add('Failed to load previously signed XML file.');
    Exit;
  end;

sbReplaceStr := TChilkatStringBuilder.Create(Self);
xmlQR.EmitXmlDecl := 0;
xmlQR.EmitCompact := 1;
sbReplaceStr.Append(xmlQR.GetXml());
sbReplaceStr.Append('<cac:Signature>');
success := sbSignedXml.ReplaceFirst('<cac:Signature>',sbReplaceStr.GetAsString());
if (success = 0) then
  begin
    Memo1.Lines.Add('Did not find <cac:Signature> in the signed XML');
    Exit;
  end;

// Save the updated signed XML.
success := sbSignedXml.WriteFile('qa_output/signedXML_withQR.xml','utf-8',0);

// ----------------------------------------
// Verify the updated signed XML to make sure we didn't invalidate the signature...
verifier := TChilkatXmlDSig.Create(Self);
success := verifier.LoadSignatureSb(sbSignedXml.ControlInterface);
if (success <> 1) then
  begin
    Memo1.Lines.Add(verifier.LastErrorText);
    Exit;
  end;

// ---------------- This is important -----------------------------------------
// Starting in Chilkat v9.5.0.92, specify "ZATCA" in uncommon options 
// to validate signed XML according to ZATCA needs.
// ----------------------------------------------------------------------------
verifier.UncommonOptions := 'ZATCA';

numSigs := verifier.NumSignatures;
verifyIdx := 0;
while verifyIdx < numSigs do
  begin
    verifier.Selector := verifyIdx;
    verified := verifier.VerifySignature(1);
    if (verified <> 1) then
      begin
        Memo1.Lines.Add(verifier.LastErrorText);
        Exit;
      end;
    verifyIdx := verifyIdx + 1;
  end;

Memo1.Lines.Add('All signatures were successfully verified.');
end;