(Delphi ActiveX) Process New Email by Scanning for Senders

Scan email and save application-selected emails to EML files with unique filenames.

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
imap: TChilkatImap;
success: Integer;
messageSet: IMessageSet;
fetchUids: Integer;
bundle: IChilkatEmailBundle;
i: Integer;
numEmails: Integer;
email: IChilkatEmail;
uidStr: WideString;
uid: Integer;
fullEmail: IChilkatEmail;
filename: WideString;

begin
// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

imap := TChilkatImap.Create(Self);

// Connect to an IMAP server.
// Use TLS
imap.Ssl := 1;
imap.Port := 993;
success := imap.Connect('imap.someMailServer.com');
if (success <> 1) then
  begin
    Memo1.Lines.Add(imap.LastErrorText);
    Exit;
  end;

// Login
success := imap.Login('myLogin','myPassword');
if (success <> 1) then
  begin
    Memo1.Lines.Add(imap.LastErrorText);
    Exit;
  end;

// Select an IMAP mailbox
success := imap.SelectMailbox('Inbox');
if (success <> 1) then
  begin
    Memo1.Lines.Add(imap.LastErrorText);
    Exit;
  end;

// We can choose to fetch UIDs or sequence numbers.
fetchUids := 1;

// Fetch messages from the mailbox using a search criteria.
// This example finds NEW emails: these are emails that have the RECENT flag set, but not the SEEN flag:
messageSet := imap.Search('NEW',fetchUids);
if (imap.LastMethodSuccess = 0) then
  begin
    Memo1.Lines.Add(imap.LastErrorText);
    Exit;
  end;

// This example will download headers, and then download
// the full email for those emails sent from a contact
// in our database.

// When downloading headers, each email object contains
// (obviously) the headers, but the body will be missing.
// Also, attachments will not be included.  However, it is
// possible to get information about the attachments
// as well as the complete size of the email.

bundle := imap.FetchHeaders(messageSet);
if (imap.LastMethodSuccess = 0) then
  begin

    Memo1.Lines.Add(imap.LastErrorText);
    Exit;
  end;

// Loop over the email objects...
i := 0;
numEmails := bundle.MessageCount;
while i < numEmails do
  begin
    email := bundle.GetEmail(i);

    // The sender's email address and name are available
    // in the From, FromAddress, and FromName properties.
    // If the sender is "Chilkat Support <support@chilkatsoft.com",
    // then the From property will hold the entire string.
    // the FromName property contains"Chilkat Support",
    // and the FromAddress property contains "support@chilkatsoft.com"
    Memo1.Lines.Add(email.From);
    Memo1.Lines.Add(email.FromAddress);
    Memo1.Lines.Add(email.FromName);

    // Assume at this point your code checks to see if the sender
    // is one in your contacts database.  If so, this is
    // the code you would write to download the entire
    // email and save it to a file.

    // The ckx-imap-uid header field is added when
    // headers are downloaded.  This makes it possible
    // to get the UID from the email object.
    uidStr := email.GetHeaderField('ckx-imap-uid');
    uid := StrToInt(uidStr);

    fullEmail := imap.FetchSingle(uid,1);
    if (imap.LastMethodSuccess = 1) then
      begin
        // You may use the GenerateFilename method to
        // generate a unique filename...

        filename := fullEmail.GenerateFilename();

        // SaveEml saves the entire email, including attachments.
        success := fullEmail.SaveEml(filename);

      end;

    Memo1.Lines.Add('--');

    i := i + 1;
  end;

// Disconnect from the IMAP server.
success := imap.Disconnect();
end;