(Delphi ActiveX) Asynchronous FTP Upload

Demonstrates an asynchronous FTP upload.

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
ftp: TChilkatFtp2;
success: Integer;
localFilepath: WideString;
remoteFilename: WideString;
task: IChilkatTask;
curPctDone: Integer;
name: WideString;
value: WideString;

begin
// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

ftp := TChilkatFtp2.Create(Self);

ftp.Hostname := 'ftp.myftpserver.com';
ftp.Username := 'mylogin';
ftp.Password := 'mypassword';

// Connect and login to the FTP server.
success := ftp.Connect();
if (success <> 1) then
  begin
    Memo1.Lines.Add(ftp.LastErrorText);
    Exit;
  end;

// Change to the remote directory where the file will be uploaded.
success := ftp.ChangeRemoteDir('junk');
if (success <> 1) then
  begin
    Memo1.Lines.Add(ftp.LastErrorText);
    Exit;
  end;

localFilepath := 'qa_data/xml/hamlet.xml';
remoteFilename := 'hamlet.xml';

// Call the async version of the PutFile method to return a task object.
// The task object is loaded, but is in the Inert state -- meaning it is
// not yet scheduled to run on Chilkat's background thread pool.
task := ftp.PutFileAsync(localFilepath,remoteFilename);
if (ftp.LastMethodSuccess = 0) then
  begin
    Memo1.Lines.Add(ftp.LastErrorText);
    Exit;
  end;

// Before starting the task, tell it to keep an in-memory log of what would've been
// ProgressInfo callbacks.
task.KeepProgressLog := 1;

// Schedule the task for running on the thread pool.  This changes the task's state
// from Inert to Live.
success := task.Run();
if (success <> 1) then
  begin
    Memo1.Lines.Add(task.LastErrorText);

    Exit;
  end;

// The application is now free to do anything else
// while the file is being uploaded.

// For this example, we'll simply sleep and periodically
// check to see if the upload is finished, and report the progress
// along the way.
curPctDone := 0;

while task.Finished <> 1 do
  begin

    if (task.PercentDone <> curPctDone) then
      begin
        curPctDone := task.PercentDone;
        Memo1.Lines.Add(IntToStr(curPctDone) + ' percent done');
      end;

    // Check the progress info log.
    // Emit any log entries..
    while (task.ProgressLogSize > 0) do
      begin
        // Get the 1st entry, emit it, and then remove it..
        name := task.ProgressInfoName(0);
        value := task.ProgressInfoValue(0);

        // Entries reporting the sent byte count will have the name "SendByteCount"
        // Entries reporting the current bytes-per-second will have the name "SendBytesPerSec"

        Memo1.Lines.Add(name + ': ' + value);
        task.RemoveProgressInfo(0);
      end;

    // Sleep 100 ms.
    task.SleepMs(100);

  end;

// Just in case there are any remaining entries...
while (task.ProgressLogSize > 0) do
  begin
    // Get the 1st entry, emit it, and then remove it..
    name := task.ProgressInfoName(0);
    value := task.ProgressInfoValue(0);
    Memo1.Lines.Add(name + ': ' + value);
    task.RemoveProgressInfo(0);
  end;

// A finished task could be one that was canceled, aborted, or truly finished.  

// If the task was "canceled", it was canceled prior to actually starting.  This could
// happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
// background thread pool scheduler.  

// If the task was "aborted", it indicates that it was canceled while running in a background thread.  
// The ResultErrorText will likely indicate that the task was aborted.

// If the task "completed", then it ran to completion, but the actual success/failure of the method
// is determined by the result obtained via a GetResult* method.  (A "completed" task will
// have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
// been aborted or canceled:
if (task.StatusInt <> 7) then
  begin
    Memo1.Lines.Add('Task did not complete.');
    Memo1.Lines.Add('task status: ' + task.Status);

    Exit;
  end;

// The PutFile method returns a boolean.  Therefore, after the task is finished,
// we can get the boolean result by calling GetResultBool.  This is the return value had
// we called PutFile synchronously.
success := task.GetResultBool();
if (success <> 1) then
  begin
    // The task's ResultErrorText contains what would have been in the LastErrorText property had
    // the GetFile method been called synchronously.
    Memo1.Lines.Add(task.ResultErrorText);
  end
else
  begin
    Memo1.Lines.Add('File uploaded asynchronously.');
  end;

success := ftp.Disconnect();
end;