(Delphi ActiveX) Dropbox File Streaming Upload

Upload a file to Drobox using a file stream. This example can upload files up to 150MB. Larger files must be uploaded with an upload session (upload_session/start).

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
rest: TChilkatRest;
success: Integer;
json: TChilkatJsonObject;
fileStream: TChilkatStream;
responseStr: WideString;
jsonResp: TChilkatJsonObject;
size: Integer;
rev: WideString;
clientModified: WideString;
ckdt: TCkDateTime;
bLocalTime: Integer;
dt: IDtObj;

begin
// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// A Dropbox access token should have been previously obtained.
// Dropbox access tokens do not expire.
// See Dropbox Access Token.

rest := TChilkatRest.Create(Self);

// Connect to Dropbox
success := rest.Connect('content.dropboxapi.com',443,1,1);
if (success <> 1) then
  begin
    Memo1.Lines.Add(rest.LastErrorText);
    Exit;
  end;

// Add request headers.
rest.AddHeader('Content-Type','application/octet-stream');
rest.AddHeader('Authorization','Bearer DROPBOX_ACCESS_TOKEN');

// The upload "parameters" contained in JSON passed in an HTTP request header.
// This is the JSON to be added in this example:
// { 
//    "path": "/Homework/lit/hamlet.xml",
//    "mode": "add",
//    "autorename": true,
//    "mute": false
// }

json := TChilkatJsonObject.Create(Self);
json.AppendString('path','/Homework/lit/hamlet.xml');
json.AppendString('mode','add');
json.AppendBool('autorename',1);
json.AppendBool('mute',0);
rest.AddHeader('Dropbox-API-Arg',json.Emit());

// Almost ready to go...
// Let's setup a file stream to point to a file.
fileStream := TChilkatStream.Create(Self);
fileStream.SourceFile := 'qa_data/xml/hamlet.xml';

// Do the upload.  The URL is https://content.dropboxapi.com/2/files/upload.
// We already connected to content.dropboxapi.com using TLS (i.e. HTTPS),
// so now we only need to specify the path "/2/files/upload".

// Note: The file is streamed directly from disk.  (The entire
// file will not be loaded into memory.)
responseStr := rest.FullRequestStream('POST','/2/files/upload',fileStream.ControlInterface);
if (rest.LastMethodSuccess <> 1) then
  begin
    Memo1.Lines.Add(rest.LastErrorText);
    Exit;
  end;

// When successful, Dropbox responds with a 200 response code.
if (rest.ResponseStatusCode <> 200) then
  begin
    // Examine the request/response to see what happened.
    Memo1.Lines.Add('response status code = ' + IntToStr(rest.ResponseStatusCode));
    Memo1.Lines.Add('response status text = ' + rest.ResponseStatusText);
    Memo1.Lines.Add('response header: ' + rest.ResponseHeader);
    Memo1.Lines.Add('response body (if any): ' + responseStr);
    Memo1.Lines.Add('---');
    Memo1.Lines.Add('LastRequestStartLine: ' + rest.LastRequestStartLine);
    Memo1.Lines.Add('LastRequestHeader: ' + rest.LastRequestHeader);
    Exit;
  end;

// The response is JSON.
jsonResp := TChilkatJsonObject.Create(Self);
jsonResp.EmitCompact := 0;
jsonResp.Load(responseStr);

// Show the JSON response.
Memo1.Lines.Add(jsonResp.Emit());

// Returns JSON that looks like this:
// { 
//   "name": "hamlet.xml",
//   "path_lower": "/homework/lit/hamlet.xml",
//   "path_display": "/Homework/lit/hamlet.xml",
//   "id": "id:74FkdeNuyKAAAAAAAAAAAQ",
//   "client_modified": "2016-06-02T23:19:00Z",
//   "server_modified": "2016-06-02T23:19:00Z",
//   "rev": "9482db15f",
//   "size": 279658
// }

// Sample code to get data from the JSON response:
size := jsonResp.IntOf('size');
Memo1.Lines.Add('size = ' + IntToStr(size));

rev := jsonResp.StringOf('rev');
Memo1.Lines.Add('rev = ' + rev);

clientModified := jsonResp.StringOf('client_modified');
ckdt := TCkDateTime.Create(Self);
ckdt.SetFromTimestamp(clientModified);
bLocalTime := 1;
dt := ckdt.GetDtObj(bLocalTime);
Memo1.Lines.Add(IntToStr(dt.Day) + '/' + IntToStr(dt.Month) + '/' + IntToStr(dt.Year) + ' ' + IntToStr(dt.Hour) + ':'
     + IntToStr(dt.Minute));
end;