(Delphi ActiveX) Create and Verify an Opaque PKCS7/CMS Signature

Demonstrates how to create a PKCS7 opaque signature, and also how to verify an opaque signature. An opaque signature is different than a detached PKCS7 signature in that it contains the original data. Verifying an opaque signature retrieves the original content.

Chilkat for Delphi Downloads Chilkat ActiveX DLL for Delphi Chilkat non-ActiveX DLL for Delphi * The examples here use the ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Chilkat_TLB;

...

procedure TForm1.Button1Click(Sender: TObject);
var
crypt: TChilkatCrypt2;
cert: TChilkatCert;
success: Integer;
privKey: TPrivateKey;
password: WideString;
originalData: WideString;
opaqueSig: WideString;
vCrypt: TChilkatCrypt2;
extractedData: WideString;

begin
// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

crypt := TChilkatCrypt2.Create(Self);

// A certificate and private key is needed to create a signature.
// Chilkat provides many different ways to load a certificate and private key, such
// as from a PFX/.p12, Java keystore, JWK, Windows registry-based certificate stores, and other sources.
// This example will load the certificate from a .crt and the private key from a .key file

cert := TChilkatCert.Create(Self);
// The LoadFromFile method will automatically detect the format and load it.
success := cert.LoadFromFile('qa_data/certs/test_12345678a.cer');
if (success <> 1) then
  begin
    Memo1.Lines.Add(cert.LastErrorText);
    Exit;
  end;

// Our private key is in an encrypted PKCS8 format.
// If you don't know the format of your key, but you do know it's encrypted,
// and requires a password, then just call any of the Chilkat methods that load
// a private key w/ a password argument.  Chilkat will auto-detect the format
// and load it correctly even if it's not the format indicated by the method name..
privKey := TPrivateKey.Create(Self);
password := '12345678a';
success := privKey.LoadPkcs8EncryptedFile('qa_data/certs/test_12345678a.key',password);
if (success <> 1) then
  begin
    Memo1.Lines.Add(privKey.LastErrorText);
    Exit;
  end;

// Set properties required for signing.

// Tell it to use the cert and private key we've loaded.
success := crypt.SetSigningCert2(cert.ControlInterface,privKey.ControlInterface);
if (success <> 1) then
  begin
    Memo1.Lines.Add(crypt.LastErrorText);
    Exit;
  end;

// Indicate we want the opaque signature in base64 format:
crypt.EncodingMode := 'base64';

// Sign the string using the "utf-8" byte representation:
crypt.Charset := 'utf-8';

// Create the opaque signature:
originalData := 'This is the string to be signed.';
opaqueSig := crypt.OpaqueSignStringENC(originalData);
if (crypt.LastMethodSuccess <> 1) then
  begin
    Memo1.Lines.Add(crypt.LastErrorText);
    Exit;
  end;

Memo1.Lines.Add(opaqueSig);

// The output looks like this:
// MIIPgQYJKoZIhvcNAQcCoIIPcjCCD24CAQExCzAJBgUrDgMCGgUAMC8GCSqGSIb3DQEHAaAiBCBUaGlzIGlzIHRoZSBzdHJpbmcgdG8gYmUgc...

// ----------------------------------------------------------------------------------------------
// Now let's verify the signature and retrieve the original data.
// We'll use a new Crypt2 object to keep things completely separate...

vCrypt := TChilkatCrypt2.Create(Self);

vCrypt.EncodingMode := 'base64';
vCrypt.Charset := 'utf-8';

extractedData := vCrypt.OpaqueVerifyStringENC(opaqueSig);
if (vCrypt.LastMethodSuccess <> 1) then
  begin
    Memo1.Lines.Add(vCrypt.LastErrorText);
    Exit;
  end;

Memo1.Lines.Add('The extracted data: ' + extractedData);

// The output is:
// The extracted data: This is the string to be signed.
end;