DataFlex

HTTP Form Authentication

See more HTTP Examples

The authentication scheme used by any given web site can vary based on its implementation. Some ways of authenticating are to send the login and password in the HTTP request header. A site that uses "Basic", "NTLM", or "Digest" authentication uses this scheme. Other sites present a web page containing an HTML form with input elements, where a user must interactively type his username and password and submit. This sends a POST to the web server with the login credentials. Form-based authentication should always occur using a secure TLS connection, otherwise the login credentials are exposed for all to see.

This example shows how to compose an HTTP POST that is equivalent to what a browser would sent when a user clicks on a form submit button. Note: If client-side Javascript is utilized to compute values that are sent as credential, then Chilkat cannot be used to duplicate it.

Suppose you have an HTML form as follows (I've eliminated all HTML tags within the form except for the input tags).

<form method="post" action="/auth.nsf?Login">
<input type="text" size="20" maxlength="256" name="username" id="user-id">
<input type="password" size="20" maxlength="256" name="password" id="pw-id">
<input type="hidden" name="redirectto" value="/web/demo.nsf/pgWelcome?Open">
<input type="submit" value="Log In">
</form>

Imagine the web site is at https://www.something123.com. The path in the "action" attribute of the form tag is the path part of the URL. Therefore, we will POST to https://www.something123.com/auth.nsf?Login

Our HTTP request will contain the following parameters: "username", "password", "redirectto", and optionally "submit". However, it is typically not necessary to add the value of the submit button input field itself. The names of the parameters are found in the "name" attribute of each input field within the HTML form. The value of a hidden input field is in the "value" attribute of the input field.

Note: This is an arbitrary example. A web site can implement forms authentication in any way it sees fit, with any number of form inputs using any names desired. There is no "standard". Every web site can and will implement it differently.

DataFlex

Use ChilkatAx-win32.pkg

Procedure Test
    Boolean iSuccess
    Handle hoHttp
    Variant vReq
    Handle hoReq
    Variant vResp
    Handle hoResp
    String sStrHtml
    String sTemp1

    Move False To iSuccess

    // This example requires the Chilkat API to have been previously unlocked.
    // See Global Unlock Sample for sample code.

    Get Create (RefClass(cComChilkatHttp)) To hoHttp
    If (Not(IsComObjectCreated(hoHttp))) Begin
        Send CreateComObject of hoHttp
    End

    // Let's begin by building an HTTP request to mimic the form.  
    // We must add the parameters, and set the path.
    Get Create (RefClass(cComChilkatHttpRequest)) To hoReq
    If (Not(IsComObjectCreated(hoReq))) Begin
        Send CreateComObject of hoReq
    End
    Send ComAddParam To hoReq "username" "mylogin"
    Send ComAddParam To hoReq "password" "mypassword"
    Send ComAddParam To hoReq "redirectto" "/web/demo.nsf/pgWelcome?Open"

    // The path part of the POST URL is obtained from the "action" attribute of the HTML form tag.
    Set ComPath Of hoReq To "/auth.nsf?Login"

    Set ComHttpVerb Of hoReq To "POST"
    Set ComFollowRedirects Of hoHttp To True

    // Collect cookies in-memory and re-send in subsequent HTTP requests, including any redirects.
    Set ComSendCookies Of hoHttp To True
    Set ComSaveCookies Of hoHttp To True
    Set ComCookieDir Of hoHttp To "memory"

    Get Create (RefClass(cComChilkatHttpResponse)) To hoResp
    If (Not(IsComObjectCreated(hoResp))) Begin
        Send CreateComObject of hoResp
    End
    Get pvComObject of hoReq to vReq
    Get pvComObject of hoResp to vResp
    Get ComHttpSReq Of hoHttp "www.something123.com" 443 True vReq vResp To iSuccess
    If (iSuccess = False) Begin
        Get ComLastErrorText Of hoHttp To sTemp1
        Showln sTemp1
        Procedure_Return
    End

    // The HTTP response object can be examined.
    // To get the HTML of the response, examine the BodyStr property (assuming the POST returns HTML)
    Get ComBodyStr Of hoResp To sStrHtml


End_Procedure