B4X

Streaming Encryption by Encrypting in Chunks

See more Encryption Examples

Encrypt data in chunks. B4X

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey("000102030405060708090A0B0C0D0E0F", "hex")
crypt.SetEncodedIV("000102030405060708090A0B0C0D0E0F", "hex")

crypt.EncodingMode = "hex"
Dim txt1 As String = "The quick brown fox jumped over the lazy dog." & Chr(13) & Chr(10)
Dim txt2 As String = "-" & Chr(13) & Chr(10)
Dim txt3 As String = "Done." & Chr(13) & Chr(10)

Dim sbEncrypted As ChilkatStringBuilder
sbEncrypted.Initialize

'  Encrypt the 1st chunk:
'  (don't worry about feeding the data to the encryptor in 
'  exact multiples of the encryption algorithm's block size.
'  Chilkat will buffer the data.)
crypt.FirstChunk = True
crypt.LastChunk = False
sbEncrypted.Append(crypt.EncryptStringENC(txt1))

'  Encrypt the 2nd chunk
crypt.FirstChunk = False
crypt.LastChunk = False
sbEncrypted.Append(crypt.EncryptStringENC(txt2))

'  Now encrypt N more chunks...
'  Remember -- we're doing this in CBC mode, so each call
'  to the encrypt method depends on the state from previous
'  calls...
crypt.FirstChunk = False
crypt.LastChunk = False
Dim i As Int
For i = 0 To 4
    sbEncrypted.Append(crypt.EncryptStringENC(txt1))
    sbEncrypted.Append(crypt.EncryptStringENC(txt2))
Next

'  Now encrypt the last chunk:
crypt.FirstChunk = False
crypt.LastChunk = True
sbEncrypted.Append(crypt.EncryptStringENC(txt3))

Log(sbEncrypted.GetAsString)

'  Now decrypt in one call.
'  (The data we're decrypting is both the first AND last chunk.)  
crypt.FirstChunk = True
crypt.LastChunk = True
Dim decryptedText As String = crypt.DecryptStringENC(sbEncrypted.GetAsString)

Log(decryptedText)

'  Note: You may decrypt in N chunks by setting the FirstChunk
'  and LastChunk properties prior to calling the Decrypt* methods.