B4X Requires Chilkat v11.0.0+
Send SOAP 1.2 Request to Web Service Requiring Authentication

This example demonstrates sending a SOAP 1.2 request to a web service that requires both HTTP authentication in the Authorization request header, as well as a service-defined password in the XML body of the request.
Chilkat B4X Downloads

Download Chilkat for B4X
B4X
Dim success As Boolean = False

'  This example assumes the Chilkat HTTP API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  --------------------------------------------------------------------------------
'  Also see Chilkat's Online WSDL Code Generator
'  to generate code and SOAP Request and Response XML for each operation in a WSDL.
'  --------------------------------------------------------------------------------

Dim http As ChilkatHttp
http.Initialize("http")

'  We are sending the following POST:

'  POST /wsSome_Testes/Service.asmx HTTP/1.1
'  Host: www.something.com
'  Content-Type: application/soap+xml; charset=utf-8
'  Content-Length: length
'  
'  <?xml version="1.0" encoding="utf-8"?>
'  <soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
'    <soap12:Body>
'      <GetXYZbyABC xmlns="http://tempuri.org/">
'        <ABCBEN>string</ABCBEN>
'        <ABC>string</ABC>
'        <NumLocal>int</NumLocal>
'        <Password>string</Password>
'        <MsgErro>string</MsgErro>
'      </GetXYZbyABC>
'    </soap12:Body>
'  </soap12:Envelope>
'  

'  First, specify the login/password for the Authorization request header (not shown in the headers above).
http.Login = "YOUR_LOGIN"
'  The need for a login domain depends on the web service..
http.LoginDomain = "YOUR_DOMAIN"
http.Password = "YOUR_PASSWORD"

'  Build the SOAP XML shown above:
'  Replace VAL_ABCBEN, VAL_ABC, VAL_NUMLOCAL, and YOUR_SOAP_BODY_PASSWORD with actual values..
Dim xml As ChilkatXml
xml.Initialize
xml.Tag = "soap12:Envelope"
xml.AddAttribute("xmlns:xsi", "http://www.w3.org/2001/XMLSchema-instance")
xml.AddAttribute("xmlns:xsd", "http://www.w3.org/2001/XMLSchema")
xml.AddAttribute("xmlns:soap12", "http://www.w3.org/2003/05/soap-envelope")
xml.UpdateAttrAt("soap12:Body|GetXYZbyABC", True, "xmlns", "http://tempuri.org/")
xml.UpdateChildContent("soap12:Body|GetXYZbyABC|ABCBEN", "VAL_ABCBEN")
xml.UpdateChildContent("soap12:Body|GetXYZbyABC|ABC", "VAL_ABC")
xml.UpdateChildContent("soap12:Body|GetXYZbyABC|NumLocal", "VAL_NUMLOCAL")
xml.UpdateChildContent("soap12:Body|GetXYZbyABC|Password", "YOUR_SOAP_BODY_PASSWORD")
xml.UpdateChildContent("soap12:Body|GetXYZbyABC|MsgErro", "x")

'  We don't need to specify the Content-Length or Host headers.  Chilkat automatically adds them.

'  Send the request...
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpStr("POST", "https://www.something.com/wsSome_Testes/Service.asmx", xml.GetXml, "utf-8", "application/soap+xml", resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


Log("Response Status Code = " & resp.StatusCode)

Dim respXml As ChilkatXml
respXml.Initialize
respXml.LoadXml(resp.BodyStr)

Log("Response XML:")
Log(respXml.GetXml)

'  The response XML should look like this:

'  <?xml version="1.0" encoding="utf-8"?>
'  <soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
'    <soap12:Body>
'      <GetXYZbyABCResponse xmlns="http://tempuri.org/">
'        <GetXYZbyABCResult>int</GetXYZbyABCResult>
'        <MsgErro>string</MsgErro>
'      </GetXYZbyABCResponse>
'    </soap12:Body>
'  </soap12:Envelope>