B4X

SMTP over Multiple Hop SSH

Demonstrates how to send email (using TCP or TLS) tunneled through mulitple-hop SSH. The scheme looks like this:

Application => ServerSSH1 => ServerSSH2 => SmtpServer

The ConnectThroughSsh and UseSsh methods are added in Chilkat version 9.5.0.55 to accomplish this task.

B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ssh1 As ChilkatSsh
ssh1.Initialize("ssh1")

'  Connect directly to the 1st SSH server.
success = ssh1.Connect("serverssh1.com", 22)
If success <> True Then
    Log(ssh1.LastErrorText)
    Return
End If


'  Authenticate using login/password:
success = ssh1.AuthenticatePw("ssh1Login", "ssh1Password")
If success <> True Then
    Log(ssh1.LastErrorText)
    Return
End If


'  Connect through the 1st SSH connection to reach a 2nd SSH server.
'  Note: Any number of SSH connections may be simultaneously tunneled through a single
'  existing SSH connection.
Dim ssh2 As ChilkatSsh
ssh2.Initialize("ssh2")
success = ssh2.ConnectThroughSsh(ssh1, "serverssh2.com", 22)
If success <> True Then
    Log(ssh2.LastErrorText)
    Return
End If


'  Authenticate with ssh2...
success = ssh2.AuthenticatePw("ssh2Login", "ssh2Password")
If success <> True Then
    Log(ssh2.LastErrorText)
    Return
End If


Dim mailman As ChilkatMailMan
mailman.Initialize("mailman")

'  Tell the mailman object to connect to the SMTP server though the ssh2 tunnel (which itself is routed through ssh1).
'  The connection looks like this:  Application => ServerSSH1 => ServerSSH2 => SMTPServer
success = mailman.UseSsh(ssh2)
If success <> True Then
    Log(mailman.LastErrorText)
    Return
End If


'  Set the SMTP server.
mailman.SmtpHost = "smtp.someserver.com"

'  Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
Dim email As ChilkatEmail
email.Initialize

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
success = email.AddTo("Chilkat Admin", "admin@chilkatsoft.com")

success = mailman.SendEmail(email)
If success <> True Then
    Log(mailman.LastErrorText)
    Return
End If


'  Close the connection with the server.  This closes the tunnel through ssh2.
success = mailman.CloseSmtpConnection
If success <> True Then
    Log("Connection to SMTP server not closed cleanly.")
End If


Log("Mail Sent!")

'  Close the connection with ssh2.  (This closes the the tunnel through ssh1.)
'  The connection with ssh1 is still alive, and may be used for more connections.
ssh2.Disconnect

ssh1.Disconnect