B4X

SOAP Request to fseservicetest.sanita.finanze.it with Smart Card Authentication (TS-CNS Italian Card)

See more HTTP Misc Examples

Demonstrates sending a SOAP request to fseservicetest.sanita.finanze.it with Smart Card (TS-CNS Italian Card). B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As ChilkatHttp
http.Initialize("http")
Dim xml As ChilkatXml
xml.Initialize

success = False

'  --------------------------------------------------------------------------------
'  Also see Chilkat's Online WSDL Code Generator
'  to generate code and SOAP Request and Response XML for each operation in a WSDL.
'  --------------------------------------------------------------------------------

'  Create the SOAP envelope...
xml.Tag = "soapenv:Envelope"
xml.AddAttribute("xmlns:soapenv", "http://schemas.xmlsoap.org/soap/envelope/")
xml.AddAttribute("xmlns:stat", "http://statoconsensirichiesta.xsd.fse.ini.finanze.it")
xml.AddAttribute("xmlns:tip", "http://tipodatistatoconsensi.xsd.fse.ini.finanze.it")
xml.UpdateChildContent("soapenv:Header", "")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoUtente", "XXXXXXAAABBBCCC")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:pinCode", "...")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoOrganizzazione", "999")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:StrutturaUtente", "123456789")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:RuoloUtente", "ZZZ")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:ContestoOperativo", "")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoAssistitoGenitoreTutore", "")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:PresaInCarico", "true")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:TipoAttivita", "READ")
xml.UpdateChildContent("soapenv:Body|stat:StatoConsensiRichiesta|stat:IdentificativoAssistitoConsenso", "ABCDEFGHIJKLM")
Dim soapEnvelope As String = xml.GetXml

Dim domain As String = "fseservicetest.sanita.finanze.it"
Dim path As String = "/FseInsServicesWeb/services/fseStatoConsensi"

Dim req As ChilkatHttpRequest
req.Initialize
req.HttpVerb = "POST"
req.SendCharset = False
req.AddHeader("Content-Type", "application/soap+xml; charset=utf-8")
req.Path = path
success = req.LoadBodyFromString(soapEnvelope, "utf-8")

'  Load the default certificate from the smartcard currently in the reader.
'  (This assumes only one reader with one smartcard containing one certificate.
'  If the situation is more complex, you can do it with Chilkat, but it requires
'  using the Chilkat certificate store object to get the desired certificate
'  from the desired smart card.)
'  
'  Note: This is for Windows-only.
Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadFromSmartcard("")
If success = False Then
    Log(cert.LastErrorText)
    Return
End If


'  Tell the Chilkat HTTP object to use the certificate for client authentication.
success = http.SetSslClientCert(cert)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


http.TlsVersion = "TLS 1.1"

Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpSReq(domain, 443, True, req, resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


Dim xmlResp As ChilkatXml
xmlResp.Initialize
success = xmlResp.LoadXml(resp.BodyStr)
Log(xmlResp.GetXml)