B4X Requires Chilkat v11.0.0+

POP3 SSH Tunneling (Port Forwarding)

Demonstrates how to connect to a POP3 server through an SSH tunnel. Reads a POP3 mailbox and display the FROM and SUBJECT header fields of each email. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The mailman object is used for receiving (POP3) 
'  and sending (SMTP) email.
Dim mailman As ChilkatMailMan
mailman.Initialize("mailman")

'  The SSH hostname may be a hostname or an 
'  IP address, such as "192.168.1.108".
'  The port is typically 22 (the standard port for SSH).
Dim sshHostname As String = "sftp.example.com"
Dim sshPort As Int = 22

'  Connect to an SSH server and establish the SSH tunnel:
success = mailman.SshOpenTunnel(sshHostname, sshPort)
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  Authenticate with the SSH server via a login/password
'  or with a public key.
'  This example demonstrates SSH password authentication.
'  Note: This is not authenticating with the POP3 server, it is
'  for authenticating with the SSH server, which is separate.
success = mailman.SshAuthenticatePw("ssh_login", "ssh_password")
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  OK, the SSH tunnel is setup.  The mailman may
'  be used exactly the same as usual, except all communications
'  are now sent through the SSH tunnel.

'  The SSH tunnel may be kept open for any number of 
'  POP3 connections.  

'  Set the POP3 server's hostname
mailman.MailHost = "mail.my-pop3-server.com"

'  Set the POP3 settings for your POP3 server:
mailman.PopUsername = "pop3_login"
mailman.PopPassword = "pop3_password"
mailman.MailPort = 995
mailman.PopSsl = True

'  Connect to the POP3 server through the already-established SSH tunnel:
success = mailman.Pop3BeginSession
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  A visual inspection of the LastErrorText after
'  a successful POP3 connection will confirm the SSH tunneling.
'  Note: If the POP3 connection uses SSL/TLS, then the SSL/TLS 
'  secure channel will be wrapped within the SSH tunnel.
Log(mailman.LastErrorText)

'  How many messages are in the POP3 inbox?
Dim numToDownload As Int = mailman.GetMailboxCount
If numToDownload > 5 Then
    numToDownload = 5
End If

If numToDownload = 0 Then
    Log("No messages in the POP3 inbox.")
    Return
End If


'  Download a max of 5 messages
Dim i As Int
Dim email As ChilkatEmail
email.Initialize
For i = 1 To numToDownload
    success = mailman.FetchOne(False, 0, i, email)
    If success = False Then
        Log(mailman.LastErrorText)
        Return
    End If


    Log(email.From)
    Log(email.Subject)
    Log("----")
Next

'  Close the connection with the POP3 server, leaving the SSH tunnel open for subsequent POP3 connections.
success = mailman.Pop3EndSession
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  Try connecting to a different POP3 server through the same aleady setup SSH tunnel:
'  Set the POP3 server's hostname
mailman.MailHost = "mail.my-pop3-server2.com"

'  Set the POP3 settings for your POP3 server:
mailman.PopUsername = "pop3_login2"
mailman.PopPassword = "pop3_password2"
mailman.MailPort = 110
mailman.PopSsl = False

success = mailman.Pop3BeginSession
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  Review the LastErrorText to see that the connection was made via the SSH tunnel:
Log(mailman.LastErrorText)

success = mailman.Pop3EndSession
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If


'  Close the SSH tunnel.
success = mailman.SshCloseTunnel
If success = False Then
    Log(mailman.LastErrorText)
    Return
End If