B4X Requires Chilkat v11.7.0+

Why a PDF Text Replacement Is Refused: the Font Rule

See more PDF Text Replacement Examples

A PDF stores glyphs drawn with particular fonts, so new text can only be drawn when the original font can draw it. This example shows the two common refusals. A font embedded as a subset carries only the glyphs the document used: a value made of other characters is refused with the reason missingGlyph, and the report names the font and the characters it lacks. A font that is neither one of the standard 14 nor embedded (here Verdana) is refused with nonStandardUnembeddedFont, because Chilkat cannot know what a viewer will draw for it. A non-embedded Arial, Times New Roman or Courier New is treated as the standard font every viewer substitutes for it. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The PDF used in this example is available at quote_subset_font.pdf
'  and letter_verdana.pdf

'  1. An embedded subset font: only the glyphs the document uses are in the PDF.
Dim pdf As ChilkatPdf
pdf.Initialize("pdf")
success = pdf.LoadFile("qa_data/pdf/quote_subset_font.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


Dim json As ChilkatJsonObject
json.Initialize
Dim jsonOut As ChilkatJsonObject
jsonOut.Initialize

'  The regular face's subset carries the characters of the quotation's text, among them the digits of
'  "58341".  A new number made of those digits can be drawn...
json.UpdateString("labels[0].label", "Quote #:")
json.UpdateString("labels[0].value", "58314")
success = pdf.TextReplace("check", json, jsonOut)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If

Log("58314: ok = " & jsonOut.BoolOf("ok"))

'  ...but "Q" and "-" are not in the subset (nothing in the quotation's regular text uses them).
json.UpdateString("labels[0].value", "Q-58341")
success = pdf.TextReplace("check", json, jsonOut)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If

Log("Q-58341: ok = " & jsonOut.BoolOf("ok"))
If jsonOut.BoolOf("ok") = False Then
    '  The problem names the font and the characters it cannot draw.
    Log("    reason: " & jsonOut.StringOf("problems[0].reason"))
    Log("    font: " & jsonOut.StringOf("problems[0].font"))
    Log("    missing: " & jsonOut.StringOf("problems[0].chars"))
End If


'  "apply" with a problem returns false and changes nothing.
success = pdf.TextReplace("apply", json, jsonOut)
Log("apply returned " & success & ", applied = " & jsonOut.BoolOf("applied"))

'  2. A font that is not embedded and not one of the standard 14.
Dim pdf2 As ChilkatPdf
pdf2.Initialize("pdf2")
success = pdf2.LoadFile("qa_data/pdf/letter_verdana.pdf")
If success = False Then
    Log(pdf2.LastErrorText)
    Return
End If


Dim json2 As ChilkatJsonObject
json2.Initialize
json2.UpdateString("labels[0].label", "Account Number:")
json2.UpdateString("labels[0].value", "0000099999")
success = pdf2.TextReplace("check", json2, jsonOut)
If success = False Then
    Log(pdf2.LastErrorText)
    Return
End If

Log("Verdana, not embedded: ok = " & jsonOut.BoolOf("ok") & ", reason: " & jsonOut.StringOf("problems[0].reason") & ", font: " & jsonOut.StringOf("problems[0].font"))

'  Sample output:

'  58314: ok = true
'  Q-58341: ok = false
'      reason: missingGlyph
'      font: AAAAAA+DejaVuSans
'      missing: Q-
'  apply returned false, applied = false
'  Verdana, not embedded: ok = false, reason: nonStandardUnembeddedFont, font: Verdana