B4X Requires Chilkat v11.7.0+

PDF Owner Password vs. User Password

See more PDF Protection Examples

Demonstrates the difference between the two passwords of an encrypted PDF. Either one opens the file. The user password gives the rights the permissions grant. The owner password gives owner rights: no restriction applies, and it is the only one that lets the security be changed or removed. Every Protection operation except getInfo needs owner rights, and Chilkat does not offer a way around that. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The PDF used in this example is available at encrypted_user_password.pdf

Dim json As ChilkatJsonObject
json.Initialize
Dim jsonOut As ChilkatJsonObject
jsonOut.Initialize

'  Opened with the user password.
Dim user As ChilkatPdf
user.Initialize("user")
user.UserPassword = "secret"
success = user.LoadFile("qa_data/pdf/encrypted_user_password.pdf")
If success = False Then
    Log(user.LastErrorText)
    Return
End If

success = user.Protection("getInfo", json, jsonOut)
If success = False Then
    Log(user.LastErrorText)
    Return
End If

Log("opened with: " & jsonOut.StringOf("loaded.openedWith"))

'  Changing the security needs owner rights, so this is refused.
success = user.Protection("removeEncryption", json, jsonOut)
If success = False Then
    Log("removeEncryption was refused: the PDF was not opened with its owner password.")
End If


'  Opened with the owner password.
Dim owner As ChilkatPdf
owner.Initialize("owner")
owner.OwnerPassword = "owner-secret"
success = owner.LoadFile("qa_data/pdf/encrypted_user_password.pdf")
If success = False Then
    Log(owner.LastErrorText)
    Return
End If

success = owner.Protection("getInfo", json, jsonOut)
If success = False Then
    Log(owner.LastErrorText)
    Return
End If

Log("opened with: " & jsonOut.StringOf("loaded.openedWith"))

'  Now it is allowed.
success = owner.Protection("removeEncryption", json, jsonOut)
If success = False Then
    Log(owner.LastErrorText)
    Return
End If

Log("removeEncryption succeeded; will be saved encrypted: " & jsonOut.BoolOf("pending.encrypted"))

'  Sample output:

'  opened with: user
'  removeEncryption was refused: the PDF was not opened with its owner password.
'  opened with: owner
'  removeEncryption succeeded; will be saved encrypted: False