B4X Requires Chilkat v11.7.0+

Change the Permissions of an Encrypted PDF

See more PDF Protection Examples

Demonstrates the changePermissions operation, which changes what an encrypted PDF permits and keeps its passwords, algorithm and scope. The JSON takes the same permissions member as the encrypt operation, and a permission that is not mentioned is granted. The operation needs owner rights. For an AES-256 PDF, load with both passwords, because the user password cannot be recovered from the owner password alone. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The PDF used in this example is available at encrypted_user_password.pdf

Dim pdf As ChilkatPdf
pdf.Initialize("pdf")

'  Changing the permissions needs owner rights.  Both passwords are given here, which is what
'  an AES-256 PDF requires for this operation.
pdf.UserPassword = "secret"
pdf.OwnerPassword = "owner-secret"
success = pdf.LoadFile("qa_data/pdf/encrypted_user_password.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  No printing and no copying.  Everything not mentioned is granted.
Dim json As ChilkatJsonObject
json.Initialize
json.UpdateString("permissions.print", "none")
json.UpdateBool("permissions.copy", False)

Dim jsonOut As ChilkatJsonObject
jsonOut.Initialize
success = pdf.Protection("changePermissions", json, jsonOut)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If

Log("print: " & jsonOut.StringOf("pending.permissions.print"))
Log("copy: " & jsonOut.BoolOf("pending.permissions.copy"))
Log("modify: " & jsonOut.BoolOf("pending.permissions.modify"))
Log("password still needed to open: " & jsonOut.BoolOf("pending.userPasswordRequired"))

success = pdf.WriteFile("qa_output/minutes_no_print.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  The same user password opens the result, now with the new permissions.
Dim reader As ChilkatPdf
reader.Initialize("reader")
reader.UserPassword = "secret"
success = reader.LoadFile("qa_output/minutes_no_print.pdf")
If success = False Then
    Log(reader.LastErrorText)
    Return
End If

Dim empty As ChilkatJsonObject
empty.Initialize
Dim info As ChilkatJsonObject
info.Initialize
success = reader.Protection("getInfo", empty, info)
If success = False Then
    Log(reader.LastErrorText)
    Return
End If

Log("saved file, print: " & info.StringOf("loaded.permissions.print"))
Log("saved file, copy: " & info.BoolOf("loaded.permissions.copy"))

'  Sample output:

'  print: none
'  copy: False
'  modify: True
'  password still needed to open: True
'  saved file, print: none
'  saved file, copy: False