B4X Requires Chilkat v11.7.0+

Change the Passwords of an Encrypted PDF

See more PDF Protection Examples

Demonstrates the changePasswords operation, which gives an encrypted PDF new user and owner passwords and keeps its algorithm and permissions. The PDF is loaded with its current passwords, the two properties are then set to the new ones, and Protection reads them at the time of the call. Both passwords are replaced, so set both: a property left empty becomes an empty password. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The PDF used in this example is available at encrypted_user_password.pdf

Dim pdf As ChilkatPdf
pdf.Initialize("pdf")

'  Load with the current passwords.
pdf.UserPassword = "secret"
pdf.OwnerPassword = "owner-secret"
success = pdf.LoadFile("qa_data/pdf/encrypted_user_password.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  The new passwords.  Protection reads the properties as they are when it is called.
pdf.UserPassword = "new-user-secret"
pdf.OwnerPassword = "new-owner-secret"

Dim json As ChilkatJsonObject
json.Initialize
Dim jsonOut As ChilkatJsonObject
jsonOut.Initialize
success = pdf.Protection("changePasswords", json, jsonOut)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  The algorithm and the permissions are kept.
Log("algorithm: " & jsonOut.StringOf("pending.algorithm"))
Log("password needed to open: " & jsonOut.BoolOf("pending.userPasswordRequired"))

success = pdf.WriteFile("qa_output/minutes_new_passwords.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  The new user password opens the result.
Dim reader As ChilkatPdf
reader.Initialize("reader")
reader.UserPassword = "new-user-secret"
success = reader.LoadFile("qa_output/minutes_new_passwords.pdf")
If success = False Then
    Log(reader.LastErrorText)
    Return
End If

success = reader.Protection("getInfo", json, jsonOut)
If success = False Then
    Log(reader.LastErrorText)
    Return
End If

Log("with the new user password, opened with: " & jsonOut.StringOf("loaded.openedWith"))

'  And so does the new owner password.
Dim owner As ChilkatPdf
owner.Initialize("owner")
owner.OwnerPassword = "new-owner-secret"
success = owner.LoadFile("qa_output/minutes_new_passwords.pdf")
If success = False Then
    Log(owner.LastErrorText)
    Return
End If

success = owner.Protection("getInfo", json, jsonOut)
If success = False Then
    Log(owner.LastErrorText)
    Return
End If

Log("with the new owner password, opened with: " & jsonOut.StringOf("loaded.openedWith"))

'  Sample output:

'  algorithm: rc4-128
'  password needed to open: True
'  with the new user password, opened with: user
'  with the new owner password, opened with: owner