B4X Requires Chilkat v11.7.0+

Shrink a PDF Losslessly

See more PDF Optimization Examples

Demonstrates the "optimize" operation with the default options, which is the lossless preset: nothing is resampled, recoloured or thrown away, so every page looks exactly as it did and all the text is still there. The changes are kept in memory until WriteFile (or WriteBd) is called. Note that the real saving is "fileSize" minus the size of the file that was written, not "bytesSaved": the rewrite also packs objects into object streams and writes a compact cross-reference stream, which belongs to no option. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The PDF used in this example is available at grand_canyon_hiking_guide.pdf

Dim pdf As ChilkatPdf
pdf.Initialize("pdf")
success = pdf.LoadFile("qa_data/pdf/grand_canyon_hiking_guide.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  An empty JSON means the default options: every lossless optimization, object streams generated,
'  old revisions dropped, deflate level 9.
Dim json As ChilkatJsonObject
json.Initialize
Dim jsonOut As ChilkatJsonObject
jsonOut.Initialize
success = pdf.Optimize("optimize", json, jsonOut)
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


'  Nothing has been written yet.  WriteFile (or WriteBd) produces the optimized PDF.
success = pdf.WriteFile("qa_output/grand_canyon_optimized.pdf")
If success = False Then
    Log(pdf.LastErrorText)
    Return
End If


Dim fac As ChilkatFileAccess
fac.Initialize
Dim sizeBefore As Int = jsonOut.IntOf("fileSize")
Dim sizeAfter As Int = fac.FileSize("qa_output/grand_canyon_optimized.pdf")

Log("before: " & sizeBefore)
Log("after:  " & sizeAfter)
Log("saved:  " & (sizeBefore - sizeAfter))

'  What the options themselves account for.  This is smaller than the real saving above, because the
'  rewrite's own gains (object streams, the cross-reference stream, the old sections left behind)
'  belong to no single option.
Log("bytesSaved (options only): " & jsonOut.IntOf("bytesSaved"))