B4X
PayPal - Void an Authorization

Voids a previously authorized payment.
Note: A fully captured authorization cannot be voided.
Note: This example requires Chilkat v9.5.0.65 or greater.
Chilkat B4X Downloads

B4X
Dim success As Boolean = False

'  Note: Requires Chilkat v9.5.0.64 or greater.

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Load our previously obtained access token. (see PayPal OAuth2 Access Token)
Dim jsonToken As ChilkatJsonObject
jsonToken.Initialize
jsonToken.LoadFile("qa_data/tokens/paypal.json")

'  Build the Authorization request header field value.
Dim sbAuth As ChilkatStringBuilder
sbAuth.Initialize
'  token_type should be "Bearer"
sbAuth.Append(jsonToken.StringOf("token_type"))
sbAuth.Append(" ")
sbAuth.Append(jsonToken.StringOf("access_token"))

'  Make the initial connection.
'  A single REST object, once connected, can be used for many PayPal REST API calls.
'  The auto-reconnect indicates that if the already-established HTTPS connection is closed,
'  then it will be automatically re-established as needed.
Dim rest As ChilkatRest
rest.Initialize("rest")
Dim bAutoReconnect As Boolean = True
success = rest.Connect("api.sandbox.paypal.com", 443, True, bAutoReconnect)
If success <> True Then
    Log(rest.LastErrorText)
    Return
End If


'  ----------------------------------------------------------------------------------------------
'  The code above this comment could be placed inside a function/subroutine within the application
'  because the connection does not need to be made for every request.  Once the connection is made
'  the app may send many requests..
'  ----------------------------------------------------------------------------------------------

Dim json As ChilkatJsonObject
json.Initialize
json.EmitCompact = False

'  This is the OAuth2 Authorization header, not to be confused with a PayPal credit card authorization...
rest.AddHeader("Authorization", sbAuth.GetAsString)
rest.AddHeader("Content-Type", "application/json")

'  The authorization ID is added to the path.
'  The authorization ID is obtained from payment records as shown here: Find Authorizations
Dim sbPath As ChilkatStringBuilder
sbPath.Initialize
sbPath.Append("/v1/payments/authorization/authorization_id/void")
Dim numReplaced As Int = sbPath.Replace("authorization_id", "0SU72290A8399291G")

'  Send the POST request containing an empty JSON body, and get the JSON response.
Dim sbJsonRequest As ChilkatStringBuilder
sbJsonRequest.Initialize
sbJsonRequest.Append("{}")

Dim sbJsonResponse As ChilkatStringBuilder
sbJsonResponse.Initialize

success = rest.FullRequestSb("POST", sbPath.GetAsString, sbJsonRequest, sbJsonResponse)
If success <> True Then
    Log(rest.LastErrorText)
    Return
End If


json.EmitCompact = False
json.LoadSb(sbJsonResponse)

Log("Response Status Code = " & rest.ResponseStatusCode)

'  Did we get a 200 success response?
If rest.ResponseStatusCode <> 200 Then
    Log(json.Emit)
    Log("Failed.")
    Return
End If


Log(json.Emit)
Log("Success.")

'  A successful JSON response:

'  	{ 
'  	  "id": "0SU72290A8399291G",
'  	  "create_time": "2016-11-26T17:31:05Z",
'  	  "update_time": "2016-11-26T17:31:10Z",
'  	  "amount": { 
'  	    "total": "6.70",
'  	    "currency": "USD",
'  	    "details": { 
'  	      "subtotal": "6.70"
'  	    }
'  	  },
'  	  "state": "voided",
'  	  "parent_payment": "PAY-62106714J93631829LA44NWI",
'  	  "links": [
'  	    { 
'  	      "href": "https://api.sandbox.paypal.com/v1/payments/authorization/0SU72290A8399291G",
'  	      "rel": "self",
'  	      "method": "GET"
'  	    },
'  	    { 
'  	      "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-62106714J93631829LA44NWI",
'  	      "rel": "parent_payment",
'  	      "method": "GET"
'  	    }
'  	  ]
'  	}