B4X Requires Chilkat v11.0.0+

Modify Parts of JSON Document

See more JSON Examples

Demonstrates how to modify parts of a JSON document. This example uses the following JSON document:

{
   "fruit": [
      	{
         "kind": "apple",
	 "count": 24,
	 "fresh": true,
	 "extraInfo": null,
	 "listA": [ "abc", 1, null, false ],
	 "objectB": { "animal" : "monkey" }
      	},
	{
         "kind": "pear",
	 "count": 18,
	 "fresh": false,
	 "extraInfo": null
	 "listA": [ "xyz", 24, null, true ],
	 "objectB": { "animal" : "lemur" }
	}
    ],
    "list" : [ "banana", 12, true, null, "orange", 12.5, { "ticker": "AAPL" }, [ 1, 2, 3, 4, 5 ] ],
    "alien" : true
}

B4X

Dim success As Boolean = False

Dim json As ChilkatJsonObject
json.Initialize

'  Load the JSON from a file.
success = json.LoadFile("qa_data/json/modifySample.json")
If success = False Then
    Log(json.LastErrorText)
    Return
End If


'  This example will not check for errors (i.e. null / false / 0 return values)...

'  Get the "list" array:

Dim listA As ChilkatJsonArray
listA.Initialize

json.ArrayOf2("list", listA)

'  Modify values in the list.

'  Change banana to plantain
success = listA.SetStringAt(0, "plantain")

'  Change 12 to 24
success = listA.SetIntAt(1, 24)

'  Change true to false
success = listA.SetBoolAt(2, False)

'  Is the 3rd item null?
Dim bNull As Boolean = listA.IsNullAt(3)

'  Change "orange" to 32.
success = listA.SetIntAt(4, 32)

'  Change 12.5 to 31.2
success = listA.SetNumberAt(5, "31.2")

'  Replace the { "ticker" : "AAPL" } object with { "ticker" : "GOOG" }
'  Do this by deleting, then inserting a new object at the same location.
success = listA.DeleteAt(6)
Dim tickerObj As ChilkatJsonObject
tickerObj.Initialize
listA.AddObjectAt2(6, tickerObj)

success = tickerObj.AppendString("ticker", "GOOG")

'  Replace "[ 1, 2, 3, 4, 5 ]" with "[ "apple", 22, true, null, 1080.25 ]"
success = listA.DeleteAt(7)
Dim aa As ChilkatJsonArray
aa.Initialize
listA.AddArrayAt2(7, aa)

success = aa.AddStringAt(-1, "apple")
success = aa.AddIntAt(-1, 22)
success = aa.AddBoolAt(-1, True)
success = aa.AddNullAt(-1)
success = aa.AddNumberAt(-1, "1080.25")

'  Get the "fruit" array
Dim aFruit As ChilkatJsonArray
aFruit.Initialize
json.ArrayAt2(0, aFruit)

'  Get the 1st element:
Dim appleObj As ChilkatJsonObject
appleObj.Initialize
aFruit.ObjectAt2(0, appleObj)

'  Modify values by member name:
success = appleObj.SetStringOf("fruit", "fuji_apple")
success = appleObj.SetIntOf("count", 46)
success = appleObj.SetBoolOf("fresh", False)
success = appleObj.SetStringOf("extraInfo", "developed by growers at the Tohoku Research Station in Fujisaki")

'  Modify values by index:

Dim pearObj As ChilkatJsonObject
pearObj.Initialize
aFruit.ObjectAt2(1, pearObj)

success = pearObj.SetStringAt(0, "bartlett_pear")
success = pearObj.SetIntAt(1, 12)
success = pearObj.SetBoolAt(2, False)
success = pearObj.SetStringAt(3, "harvested in late August to early September")

json.EmitCompact = False
Log(json.Emit)