B4X Requires Chilkat v11.0.0+

Using Client Certificate w/ IMAP SSL

Demonstrates how to use a client-side certificate with an IMAP SSL connection. The SetSslClientCert method is called to specify a certificate to be used for the SSL connection. B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim imap As ChilkatImap
imap.Initialize("imap")

'  To use a secure SSL connection, set SSL and the port:
imap.Ssl = True
'  The typical port for IMAP SSL is 993
imap.Port = 993

'  Load a certificate from a PFX file and use it.
'  Note: Other methods are available to load pre-installed
'  certificates from registry-based certificate stores.

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
Dim certStore As ChilkatCertStore
certStore.Initialize
'  The 1st argument is the filename, the 2nd arg is the 
'  PFX file's password:
success = certStore.LoadPfxFile("myCertWithPrivateKey.pfx", "secret")
If success = False Then
    Log(certStore.LastErrorText)
    Return
End If


'  Find the certificate by the subject common name:
Dim jsonCN As ChilkatJsonObject
jsonCN.Initialize
jsonCN.UpdateString("CN", "cert common name")

Dim cert As ChilkatCert
cert.Initialize("cert")
success = certStore.FindCert(jsonCN, cert)
If success = False Then
    Log(certStore.LastErrorText)
    Return
End If


'  If a PFX file is known to contain a single certificate,
'  you may load it directly into a Chilkat certificate object.
'  This snippet of source code shows how:
Dim cert2 As ChilkatCert
cert2.Initialize("cert2")
'  The 1st argument is the filename, the 2nd arg is the 
'  PFX file's password:
success = cert2.LoadPfxFile("myClientCert.pfx", "secret")
If success = False Then
    Log(cert.LastErrorText)
    Return
End If


'  Use the cert:
success = imap.SetSslClientCert(cert)

'  Connect to an IMAP server.
success = imap.Connect("imap.example.com")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Login
success = imap.Login("myLogin", "myPassword")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Get the message IDs of all the emails in the mailbox
Dim fetchUids As Boolean = True
Dim messageSet As ChilkatMessageSet
messageSet.Initialize
success = imap.QueryMbx("ALL", fetchUids, messageSet)
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Fetch the emails into a bundle object:
Dim bundle As ChilkatEmailBundle
bundle.Initialize
Dim headersOnly As Boolean = False
success = imap.FetchMsgSet(headersOnly, messageSet, bundle)
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Loop over the bundle and display the FROM and SUBJECT of each.
Dim email As ChilkatEmail
email.Initialize
Dim i As Int = 0
Dim numEmails As Int = bundle.MessageCount
Do While i < numEmails
    bundle.EmailAt(i, email)

    Log(email.From)
    Log(email.Subject)
    Log("--")
    i = i + 1
Loop

'  Disconnect from the IMAP server.
success = imap.Disconnect