B4X

IMAP Get Quota Root

Sends the GETQUOTAROOT command to the IMAP server to get the quota root for a given mailbox. This also provides quota information for the given mailbox.

The GetQuotaRoot method is available in Chilkat starting at v9.5.0.58, and is only available for IMAP servers that support the QUOTA extension.

The information is returned in JSON format. This example demonstrates how to parse the JSON to get the desired information.

Typically, the quota root for the Inbox is the empty string.

B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim imap As ChilkatImap
imap.Initialize("imap")

'  Use TLS
imap.Ssl = True
imap.Port = 993
success = imap.Connect("MY-IMAP-DOMAIN")
If success <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  Authenticate
success = imap.Login("MY-IMAP-LOGIN", "MY-IMAP-PASSWORD")
If success <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  First check to see if the IMAP server supports the QUOTA extension.
Dim caps As String = imap.Capability
If imap.LastMethodSuccess <> True Then
    Log(imap.LastErrorText)
    Return
End If


If imap.HasCapability("QUOTA", caps) <> True Then
    Log("IMAP server does not support the QUOTA extension.")
    Return
End If


Dim jsonStr As String = imap.GetQuotaRoot("Inbox")
If imap.LastMethodSuccess <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  The JSON string will look something like this:
'  {"QUOTAROOT":{"mailbox":"Inbox","root":""},"QUOTA":{"root":"","resource":"STORAGE","used":22216,"max":15728640}}
Log(jsonStr)

'  This is easy to parse...
Dim json As ChilkatJsonObject
json.Initialize
json.Load(jsonStr)

'  Get the quota root for Inbox, which is an empty string in the case above.
Dim quotaRoot As String = json.StringOf("QUOTAROOT.root")
Log("Quota Root for Inbox: [" & quotaRoot & "]")

'  Now get the resource name (which can be STORAGE or MESSAGE) and the used/max values.
'  Most servers have STORAGE quotas, which are for total capacity.  For example, GMail's
'  STORAGE quota is 15GB (at the time of writing this example).
'  A MESSAGE quota sets a limit on the number of messages.
Dim resourceName As String = json.StringOf("QUOTA.resource")
Dim quotaUsed As Int = json.IntOf("QUOTA.used")
Dim quotaMax As Int = json.IntOf("QUOTA.max")

Log("Resource: " & resourceName)
Log("Quota Used (in KB): " & quotaUsed)
Log("Quota Max (in KB): " & quotaMax)

'  Disconnect from the IMAP server.
success = imap.Disconnect