B4X Requires Chilkat v11.0.0+

Copy an Email from One Mailbox to Another

Copies an email from one IMAP folder to another. After running this example, copies of the email will be present in both source and destination folders. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example copies an email from one mailbox to another.
Dim imap As ChilkatImap
imap.Initialize("imap")

'  Turn on session logging:
imap.KeepSessionLog = True

'  Connect to an IMAP server.
'  Use TLS
imap.Ssl = True
imap.Port = 993
success = imap.Connect("imap.example.com")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Login
success = imap.Login("***", "***")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox.testing.a")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


Dim fetchUids As Boolean = True

'  Get the message IDs for all emails having "Re:" in the subject.
Dim messageSet As ChilkatMessageSet
messageSet.Initialize
success = imap.QueryMbx("SUBJECT Re:", fetchUids, messageSet)
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Copy the messages from "Inbox.testing.a" to "Inbox.testing.b" in one call to CopyMultiple:
success = imap.CopyMultiple(messageSet, "Inbox.testing.b")
If success = False Then
    Log(imap.LastErrorText)
    Return
End If


'  Alternatively, loop over each message in the set and
'  copy each separately:
Dim i As Int = 0
Do While i < messageSet.Count

    Dim msgId As Int = messageSet.GetId(i)
    Dim isUid As Boolean = messageSet.HasUids

    success = imap.Copy(msgId, isUid, "Inbox.testing.c")
    If success = False Then
        Log(imap.LastErrorText)
        Return
    End If

    i = i + 1
Loop

'  Display the session log.
Log(imap.SessionLog)

'  Disconnect from the IMAP server.
success = imap.Disconnect