B4X Requires Chilkat v11.0.0+

How to Access Parts of a multipart/related HTTP Response

See more HTTP Examples

Demonstrates how to access the parts of a multipart/related response. This example sends a ficticious multipart/related request, and handles a ficticious multipart/related response.

We send the following multipart/related request:

Content-Type: multipart/related; start-info="text/xml"; type="application/xop+xml"; boundary="----=_Part_0_1744155.1118953559416"
Content-Length: 3453
SOAPAction: "some-SOAP-action"

------=_Part_1_4558657.1118953559446
Content-Type: application/xop+xml; type="text/xml"; charset=utf-8

<soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
  <soap:Body>
    <Detail xmlns="http://example.org/mtom/data">
      <image>
        <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org" />
      </image>
    </Detail>
  </soap:Body>
</soap:Envelope>

------=_Part_1_4558657.1118953559446
Content-Type: image/jpeg
Content-ID: <5aeaa450-17f0-4484-b845-a8480c363444@example.org>


... binary data ...

B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As ChilkatHttp
http.Initialize("http")

Dim soapXml As ChilkatXml
soapXml.Initialize

'  Build the following SOAP XML

'  <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'    <soap:Body>
'      <Detail xmlns="http://example.org/mtom/data">
'        <image>
'          <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org" />
'        </image>
'      </Detail>
'    </soap:Body>
'  </soap:Envelope>

soapXml.Tag = "soap:Envelope"
soapXml.AddAttribute("xmlns:soap", "http://schemas.xmlsoap.org/soap/envelope/")
soapXml.UpdateAttrAt("soap:Body|Detail", True, "xmlns", "http://example.org/mtom/data")
soapXml.UpdateAttrAt("soap:Body|Detail|image|xop:Include", True, "xmlns:xop", "http://www.w3.org/2004/08/xop/include")
soapXml.UpdateAttrAt("soap:Body|Detail|image|xop:Include", True, "href", "cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org")

soapXml.EmitXmlDecl = False
Dim xmlBody As String = soapXml.GetXml
Log(xmlBody)

Dim req As ChilkatHttpRequest
req.Initialize
req.HttpVerb = "POST"
req.Path = "/something/someTarget"

req.ContentType = "multipart/related; start-info=" & Chr(34) & "text/xml" & Chr(34) & "; type=" & Chr(34) & "application/xop+xml" & Chr(34)
req.AddHeader("SOAPAction", "some-SOAP-action")

success = req.AddStringForUpload2("", "", xmlBody, "utf-8", "application/xop+xml; type=" & Chr(34) & "text/xml" & Chr(34) & "; charset=utf-8")

'  The bytes will be sent as binary (not base64 encoded).
success = req.AddFileForUpload2("", "qa_data/jpg/starfish.jpg", "image/jpeg")

'  The JPEG data is the 2nd sub-part, and therefore is at index 1 (the first sub-part is at index 0)
success = req.AddSubHeader(1, "Content-ID", "<5aeaa450-17f0-4484-b845-a8480c363444@example.org>")

http.FollowRedirects = True

Dim useTls As Boolean = True
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpSReq("www.example.org", 443, useTls, req, resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


'  Imagine the HTTP response is multipart related and is something like this:

'  HTTP/1.1 200 OK
'  Cache-Control: no-cache, no-store
'  Pragma: no-cache
'  Transfer-Encoding: chunked
'  Content-Type: multipart/related; boundary=------------080001080500020607080905
'  Expires: -1
'  Server: Microsoft-IIS/10.0
'  X-AspNet-Version: 4.0.30319
'  X-Powered-By: ASP.NET
'  Date: Wed, 19 Feb 2020 15:27:06 GMT
'  
'  --------------080001080500020607080905
'  Content-Type: application/xop+xml; charset=iso-8859-1
'  Content-Id: RootPart
'  Content-Transfer-Encoding: binary
'  
'  <?xml version="1.0" encoding="iso-8859-1"?>
'  <soapenv:Envelope xmlns:xcpt="...">
'    <soapenv:Header />
'    <soapenv:Body>
'      <xres:Transport profile="http://something.example.com/..." version="1.4">
'        <xres:TransportHeader>
'  	...
'  	...
'        </xres:TransportHeader>
'        <xres:TransportBody />
'      </xres:Transport>
'    </soapenv:Body>
'  </soapenv:Envelope>
'  --------------080001080500020607080905--

'  To get the XML, load the full MIME of the response into a Chilkat MIME object.  Then get the body of the 1st sub-part.
Dim mime As ChilkatMime
mime.Initialize
mime.LoadMime(resp.FullMime)

'  Your code might verify that the Content-Type is indeed multipart/related.
Log(mime.ContentType)
Log("num parts = " & mime.NumParts)

'  Assuming it is, and the number of sub-parts is > 0
If mime.NumParts > 0 Then

    Dim part0 As ChilkatMime
    part0.Initialize
    mime.PartAt(0, part0)

    '  The Content-Type (in this ficticious example) should be "application/xop+xml"
    Log("sub-part Content-Type: " & part0.ContentType)
    '  Now get the XML 
    Dim subPartXmlBody As String = part0.GetBodyDecoded
    Log(subPartXmlBody)
End If