B4X

Calculate HRMC IRMark

See more XML Digital Signatures Examples

Demonstrates how to calculate an IRmark for an HMRC GovTalkMessage XML document.

Chilkat B4X Downloads

B4X

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  First build a sample (but incomplete) GovTalkMessage.
'  You can replace this code with a call to LoadXml or LoadXmlFile..
'  
'  Note: The online tool at https://tools.chilkat.io/xmlCreate.cshtml
'  can be used to generate XML code that creates a given XML document.
Dim xml As ChilkatXml
xml.Initialize
xml.Tag = "GovTalkMessage"
xml.AddAttribute("xmlns", "http://www.govtalk.gov.uk/CM/envelope")
xml.UpdateAttrAt("Body|Message", True, "xmlns", "urn:g3.ge:dea:call:SendDocument:v1")
xml.UpdateChildContent("Body|Message", "................")

'  This is the XML created:
'  <?xml version="1.0" encoding="utf-8" ?>
'  <GovTalkMessage xmlns="http://www.govtalk.gov.uk/CM/envelope">
'      <Body>
'          <Message xmlns="urn:g3.ge:dea:call:SendDocument:v1">................</Message>
'      </Body>
'  </GovTalkMessage>

Log(xml.GetXml)

'  Canonicalize the XML (using C14N)
Dim xdsig As ChilkatXmlDSig
xdsig.Initialize
Dim withComments As Boolean = False
Dim canonXml As String = xdsig.CanonicalizeXml(xml.GetXml, "C14N", withComments)

'  Return the base64 SHA-1 HASH of the canonical XML.
Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")
crypt.HashAlgorithm = "sha1"
crypt.EncodingMode = "base64"
Dim irmark As String = crypt.HashStringENC(canonXml)

Log("IRMark = " & irmark)