B4X Requires Chilkat v11.0.0+
Upload String to Google Cloud Storage

Demonstrates how to upload an in-memory string to Google Cloud Storage.
Chilkat B4X Downloads

B4X
Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example uses a previously obtained access token having permission for the 
'  scope "https://www.googleapis.com/auth/cloud-platform"

'  In this example, Get Google Cloud Storage OAuth2 Access Token, 
'  the service account access token was saved to a text file.  This example fetches the access token from the file..
Dim sbToken As ChilkatStringBuilder
sbToken.Initialize
sbToken.LoadFile("qa_data/tokens/googleCloudStorageAccessToken.txt", "utf-8")

'  Send a POST equivalent to this curl command.
'  The content of the file is contained in the request body.

'  curl -X POST --data-binary @[OBJECT] \
'      -H "Authorization: Bearer [OAUTH2_TOKEN]" \
'      -H "Content-Type: [OBJECT_CONTENT_TYPE]" \
'      "https://www.googleapis.com/upload/storage/v1/b/[BUCKET_NAME]/o?uploadType=media&name=[OBJECT_NAME]"

Dim http As ChilkatHttp
http.Initialize("http")
http.AuthToken = sbToken.GetAsString

'  Create an XML document, and write it to a StringBuilder.
'  We'll be uploading this XML document.
Dim xml As ChilkatXml
xml.Initialize
xml.Tag = "note"
xml.UpdateChildContent("to", "Tove")
xml.UpdateChildContent("from", "Jani")
xml.UpdateChildContent("heading", "Reminder")
xml.UpdateChildContent("body", "Don't forget me this weekend!")

'  Write the XML to sbXml.
Dim sbXml As ChilkatStringBuilder
sbXml.Initialize
xml.GetXmlSb(sbXml)

'  sbXml contains this:

'  <note>
'      <to>Tove</to>
'      <from>Jani</from>
'      <heading>Reminder</heading>
'      <body>Don't forget me this weekend!</body>
'  </note>

'  Construct a URL to upload to an object named "test.xml" in the "chilkat-ocean" bucket.
http.SetUrlVar("bucket_name", "chilkat-ocean")
http.SetUrlVar("object_name", "test.xml")
Dim url As String = "https://www.googleapis.com/upload/storage/v1/b/{$bucket_name}/o?uploadType=media&name={$object_name}"

Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpSb("POST", url, sbXml, "utf-8", "application/xml", resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


Dim responseCode As Int = resp.StatusCode
If responseCode = 401 Then
    Log(resp.BodyStr)
    Log("If invalid credentials, then it is likely the access token expired.")
    Log("Your app should automatically fetch a new access token and re-try.")
    Return
End If


Log("Response code: " & responseCode)
Log("Response body")
Log(resp.BodyStr)

'  A successful response looks like this:
'  Response code: 200
'  Response body
'  {
'   "kind": "storage#object",
'   "id": "chilkat-ocean/test.xml/1502669565429870",
'   "selfLink": "https://www.googleapis.com/storage/v1/b/chilkat-ocean/o/test.xml",
'   "name": "test.xml",
'   "bucket": "chilkat-ocean",
'   "generation": "1502669565429870",
'   "metageneration": "1",
'   "contentType": "application/xml",
'   "timeCreated": "2017-08-14T00:12:45.379Z",
'   "updated": "2017-08-14T00:12:45.379Z",
'   "storageClass": "MULTI_REGIONAL",
'   "timeStorageClassUpdated": "2017-08-14T00:12:45.379Z",
'   "size": "181",
'   "md5Hash": "TCR0L7TWsw2TzOvfNvgEfA==",
'   "mediaLink": "https://www.googleapis.com/download/storage/v1/b/chilkat-ocean/o/test.xml?generation=1502669565429870&alt=media",
'   "crc32c": "ZFd5sA==",
'   "etag": "CO6Qpq241dUCEAE="
'  }