B4X
Create GMail Draft

Demonstrates how to create a new GMail draft email.
Chilkat B4X Downloads

B4X
Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Use the Chilkat Email API to create or load an email.
Dim email As ChilkatEmail
email.Initialize
email.Subject = "This is a test GMail email created using Chilkat."
email.Charset = "utf-8"
email.AddPlainTextAlternativeBody("This is a test")
email.AddHtmlAlternativeBody("<html><body><p>This is a <b>test</b></body></html>")

'  We'll need to get the full MIME of the email encoded to a base64url string.
Dim sbMime As ChilkatStringBuilder
sbMime.Initialize
email.GetMimeSb(sbMime)
sbMime.Encode("base64url", "utf-8")

'  The body of the HTTP request will be JSON..
Dim json As ChilkatJsonObject
json.Initialize
json.UpdateSb("message.raw", sbMime)

'  Upload the email to GMail as a draft.
Dim http As ChilkatHttp
http.Initialize("http")
http.AuthToken = "GMAIL-ACCESS-TOKEN"

Dim url As String = "https://www.googleapis.com/gmail/v1/users/me/drafts"
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpJson("POST", url, json, "application/json", resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


'  A status code of 200 indicates success.
Log("Response status code: " & resp.StatusCode)
Log("Response body:")
Log(resp.BodyStr)

'  The response body contains JSON.
'  Use the online tool at Generate JSON Parsing Code
'  to generate JSON parsing code.

'  A sample successful JSON response:

'  {
'   "id": "r-2607584557788895307",
'   "message": {
'    "id": "166f09932c662e93",
'    "threadId": "166f09932c662e93",
'    "labelIds": [
'     "DRAFT"
'    ]
'   }
'  }