B4X Requires Chilkat v10.1.2+

Secure FTP with Client Certificate

See more FTP Examples

Chilkat FTP2 provides the ability to use a client certificate with secure FTP (implicit or explicit SSL/TLS). This example demonstrates how to load a certificate from a .pfx and use it as the client-side SSL cert. Note: Client-side certificates are only needed in situations where the server demands one. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ftp As ChilkatFtp2
ftp.Initialize("ftp")

ftp.Hostname = "ftp.example.com"
ftp.Port = 21
ftp.Username = "test"
ftp.Password = "test"

'  This example will use explict TLS/SSL.
'  Establish an explicit secure channel after connection
'  on the standard FTP port 21.
ftp.AuthTls = True

'  The Ssl property is for establishing an implicit SSL connection
'  on port 990.  Because this example uses explicit SSL, it 
'  should remain False.
ftp.Ssl = False

'  Load a certificate from a .pfx
'  A PFX may contain several certs, including the certificates
'  in a chain of authority.
Dim certStore As ChilkatCertStore
certStore.Initialize
Dim password As String
password = "***"
'  Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("chilkat.pfx", password)
If success <> True Then
    Log(certStore.LastErrorText)
    Return
End If


'  Find the desired certificate.
Dim jsonCN As ChilkatJsonObject
jsonCN.Initialize
jsonCN.UpdateString("CN", "cert common name")

Dim cert As ChilkatCert
cert.Initialize("cert")
success = certStore.FindCert(jsonCN, cert)
If success = False Then
    Log("Certificate not found!")
    Return
End If


'  Use this certificate for our secure (SSL/TLS) connection:
success = ftp.SetSslClientCert(cert)

'  Connect and login to the FTP server.  The connection is 
'  made secure because of the AuthTls setting.
success = ftp.Connect
If success <> True Then
    Log(ftp.LastErrorText)
    Return
Else
    '  LastErrorText contains information even when
    '  successful. This allows you to visually verify
    '  that the secure connection actually occurred.
    Log(ftp.LastErrorText)
End If


Log("Secure FTP Channel Established!")

'  Do whatever you're doing to do ...
'  upload files, download files, etc...

'  .....
'  .....

success = ftp.Disconnect