B4X

AES Encryption

See more Encryption Examples

AES encryption. The Chilkat encryption component supports 128-bit, 192-bit, and 256-bit AES encryption in ECB (Electronic Cookbook), CBC (Cipher-Block Chaining), and other modes. B4X

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

'  AES is also known as Rijndael.		
crypt.CryptAlgorithm = "aes"

'  CipherMode may be "ecb", "cbc", "ofb", "cfb", "gcm", etc.
'  Note: Check the online reference documentation to see the Chilkat versions
'  when certain cipher modes were introduced.
crypt.CipherMode = "cbc"

'  KeyLength may be 128, 192, 256
crypt.KeyLength = 256

'  The padding scheme determines the contents of the bytes
'  that are added to pad the result to a multiple of the
'  encryption algorithm's block size.  AES has a block
'  size of 16 bytes, so encrypted output is always
'  a multiple of 16.
crypt.PaddingScheme = 0

'  EncodingMode specifies the encoding of the output for
'  encryption, and the input for decryption.
'  It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

'  An initialization vector is required if using CBC mode.
'  ECB mode does not use an IV.
'  The length of the IV is equal to the algorithm's block size.
'  It is NOT equal to the length of the key.
Dim ivHex As String = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV(ivHex, "hex")

'  The secret key must equal the size of the key.  For
'  256-bit encryption, the binary secret key is 32 bytes.
'  For 128-bit encryption, the binary secret key is 16 bytes.
Dim keyHex As String = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey(keyHex, "hex")

'  Encrypt a string...
'  The input string is 44 ANSI characters (i.e. 44 bytes), so
'  the output should be 48 bytes (a multiple of 16).
'  Because the output is a hex string, it should
'  be 96 characters long (2 chars per byte).
Dim encStr As String = crypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
Log(encStr)

'  This is the encrypted output in hex format:
'  4846F83AA211E239AA62A21F527F089EE9DDBEAD30EE15D4E79B607A621B97BEDB9B6F00A9B21F1B43A50B4C1BE0EDF2

'  Now decrypt:
Dim decStr As String = crypt.DecryptStringENC(encStr)
Log(decStr)

'  This is the decrypted string:
'  The quick brown fox jumps over the lazy dog.