(AutoIt) S3 Rename File

See more Amazon S3 (new) Examples

Demonstrates how to rename a file on Amazon S3.

Renaming an object (file) in AWS S3 using the AWS S3 API involves copying the object to a new location with the desired name and then deleting the original object.

For more information, see https://docs.aws.amazon.com/AmazonS3/latest/API/API_CopyObject.html#API_CopyObject_Examples

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.

$oRest = ObjCreate("Chilkat.Rest")

; Connect to the Amazon AWS REST server in the desired region.
Local $bTls = True
Local $iPort = 443
Local $bAutoReconnect = True
Local $bSuccess = $oRest.Connect("s3-us-west-2.amazonaws.com",$iPort,$bTls,$bAutoReconnect)

; Provide AWS credentials.
$oAuthAws = ObjCreate("Chilkat.AuthAws")
$oAuthAws.AccessKey = "AWS_ACCESS_KEY"
$oAuthAws.SecretKey = "AWS_SECRET_KEY"
$oAuthAws.ServiceName = "s3"

; This particular bucket is in the Oregon region, as opposed to the US Standard,
; therefore the Region must be set appropriately.
; Also note that we connected to "s3-us-west-2.amazonaws.com".
$oAuthAws.Region = "us-west-2"

$oRest.SetAuthAws($oAuthAws)

; Set the bucket name via the HOST header.
; In this case, the bucket name is "chilkat.qa".
; Note that the Host header should use "bucketName.s3.amazonaws.com", not "bucketName.s3-us-west-2.amazonaws.com"
$oRest.Host = "chilkat.qa.s3.amazonaws.com"

; Copy /images/sea_creatures/starfish.jpg to /images/sea_creatures/starfish3.jpg
; Notice here that the x-amz-copy-source includes the bucket in the source path,
; but the target path passed to FullRequestNoBody does NOT contain the bucket (because the bucket
; was already specified in the Host header).
$oRest.AddHeader("x-amz-copy-source","/chilkat.qa/images/sea_creatures/starfish.jpg")

$oSbResponse = ObjCreate("Chilkat.StringBuilder")
$bSuccess = $oRest.FullRequestNoBodySb("PUT","/images/sea_creatures/starfish3.jpg",$oSbResponse)
If ($bSuccess = False) Then
    ConsoleWrite($oRest.LastErrorText & @CRLF)
    Exit
EndIf

; When successful, the S3 Storage service will respond with a 200 or 204 response code,
; with an XML body.  
If ($oRest.ResponseStatusCode <> 200) Then
    ; Examine the request/response to see what happened.
    ConsoleWrite("response status code = " & $oRest.ResponseStatusCode & @CRLF)
    ConsoleWrite("response status text = " & $oRest.ResponseStatusText & @CRLF)
    ConsoleWrite("response header: " & $oRest.ResponseHeader & @CRLF)
    ConsoleWrite("response body: " & $oSbResponse.GetAsString() & @CRLF)
    ConsoleWrite("---" & @CRLF)
    ConsoleWrite("LastRequestStartLine: " & $oRest.LastRequestStartLine & @CRLF)
    ConsoleWrite("LastRequestHeader: " & $oRest.LastRequestHeader & @CRLF)
EndIf

ConsoleWrite($oSbResponse.GetAsString() & @CRLF)
ConsoleWrite("Copy Successful." & @CRLF)

; --------------------------------------
; Now we can delete the original file..
; --------------------------------------

; We no longer want to send the x-amz-copy-source header.  Remove it.
$oRest.RemoveHeader("x-amz-copy-source")

$bSuccess = $oRest.FullRequestNoBodySb("DELETE","/images/sea_creatures/starfish.jpg",$oSbResponse)
If ($bSuccess = False) Then
    ConsoleWrite($oRest.LastErrorText & @CRLF)
    Exit
EndIf

; If successfully deleted, the response status code is 204 and the response body text will be empty.
Local $iStatusCode = $oRest.ResponseStatusCode
ConsoleWrite("Response status code = " & $iStatusCode & @CRLF)
ConsoleWrite("Response text = " & @CRLF)
ConsoleWrite($oSbResponse.GetAsString() & @CRLF)